Just hardcode the package name you wish to skip to:

$self->SomeClass::method(...);
[download]

Example:

#!/usr/bin/env perl

use strict;
use warnings;

{
    package Animal;
    sub foo {
        my $class = shift;
        print __PACKAGE__, "\n";
    }
}

{
    package Mammal;
    use base "Animal";
    sub foo {
        my $class = shift;
        print __PACKAGE__, "\n";
        $class->SUPER::foo(@_);
    }
}

{
    package Primate;
    use base "Mammal";
    sub foo {
        my $class = shift;
        print __PACKAGE__, "\n";
        $class->SUPER::foo(@_);
    }
}

{
    package Monkey;
    use base "Primate";
    sub foo {
        my $class = shift;
        print __PACKAGE__, "\n";
        $class->Mammal::foo(@_);  # skip over Primate::foo
    }
}

Monkey->foo;
[download]

Here's an alternative Monkey::foo sub that avoids hard-coding the Mammal class name:

sub foo {
    my $class = shift;
    print __PACKAGE__, "\n";
    require mro;
    my $grandparent = $class->mro::get_linear_isa->[2];
    my $gp_method   = $grandparent->can('foo');
    $class->$gp_method(@_);
}
[download]

Or even:

sub foo {
    my $class = shift;
    print __PACKAGE__, "\n";
    require mro;
    $class->${\ $class->mro::get_linear_isa->[2]->can("foo") }(@_);
}
[download]

Note that mro requires Perl 5.10 or better, but there exists a MRO::Compat that provides an alternative implementation of mro::get_linear_isa for Perl 5.8.