$data{$problem}{$year}{$month}=$count

you could also go for

$data{$problem}{"$year-$month"}=$count

Now what is the real question?

How to get the input from SQL or how to get the output to GD::Graph ?

well, I was going to iterate through the data from SQL - I can already retrieve that. I was just confused on how to store and then retrieve the data. And yes, the next part of the problem will be how to arrange the data into the various series to give to GD::Graph.

If you are likely to plot across years or over a period of say the last x months, then it may be convenient to convert your year and months into a 'period number'. Then you can store the data in a hash like this ;

$data{'category'}[period]

Storing a string of month/year in another array using the same period numbers as the index makes it easy to build the first record of your plot data.

Here is an example of what I mean with your data expanded into 2014.

#perl
use strict;
use GD::Graph;
use GD::Graph::bars;
my $YEAR1 = 2013;
my @period=();
my %y_data=();
my @x_legend=();

# stroe data
while (<DATA>){
  chomp;
  my ($m,$y,$cat,$n) = split ',',$_;
  # convert year/month to period number
  my $pd = ym_to_pd($y,$m);
  $period[$pd] = "$m/$y";
  $y_data{$cat}[$pd] = $n;
}

# graph data
my @y_plotdata;
push @y_plotdata,[@period];
for my $cat (sort keys %y_data){
  push @x_legend,$cat;
  push @y_plotdata,[@{$y_data{$cat}}];
}

# create graph
my $my_graph = GD::Graph::bars->new(800,600);
$my_graph->set(
  x_label => 'X Label',
  y_label => 'Y label', 
  title => 'Title',
); 
$my_graph->set_legend(@x_legend); 
my $img = $my_graph->plot(\@y_plotdata) or die $my_graph->error;

# save image
open(IMG,'>','plot.gif') or die "$!";
binmode IMG;
print IMG $img->png;
close IMG;


# convert year,month to period
sub ym_to_pd {
  my ($yr,$mth) = @_;
  return ($yr - $YEAR1) * 12 + $mth;
}

# convert period to year.month
sub pd_to_ym {
  my $ix = shift;
  my $yr  = int(($ix-1)/12)+$YEAR1;
  my $mth = $ix-12*($yr-$YEAR1);
  return ($yr,$mth);
}

#test_periods();
sub test_periods {
  for my $y (2013..2015){
    for my $m (1..12){
      my $pd = ym_to_pd($y,$m);
      my ($yr,$mth) = pd_to_ym($pd);
      print "$y $m => $pd => $yr $mth\n";
    }
  }
}

__DATA__
3,2013,Address,1
2,2013,Equipment,13
3,2013,Equipment,18
4,2013,Equipment,17
5,2013,Equipment,8
3,2013,Database Reconciliation,3
5,2013,Database Reconciliation,3
2,2013,Design/Process,123
3,2013,Design/Process,74
4,2013,Design/Process,42
5,2013,Design/Process,30
1,2014,Design/Process,30
[download]

poj

I never used GD::Graph, but if you need help you should

a) read the docs / tutorials /search results

b) show what you already tried

c) identify your problems

d) ask concrete questions, instead for complete solutions.

We love teaching how to fish ... =)

Cheers Rolf

( addicted to the Perl Programming Language)