in reply to Re: json return value
in thread json return value

I give up on this json/perl stuff. The cgi stuff looks as if it just responds to html pages not anything else and with not having permission to access cgi files, its just too difficult. All I want is to send an integer to a website from a standalone perl client using post and get an integer returned. Is it that difficult? Embedded development is easy compared to this. I'm beginning to lose my belief in this Perl religion !! I think I'll stick to the C sinners club.

Replies are listed 'Best First'.
Re^3: json return value
by tobyink (Canon) on Jul 14, 2013 at 01:36 UTC

    It's really not that difficult...

    Server

    use v5.14;
use CGI ();
use JSON::PP ();

my $q     = 'CGI'->new;
my $json  = 'JSON::PP'->new;
my $input = $json->decode( $q->param('POSTDATA') );

my $a = $input->{a};
my $b = $input->{b};
my $c = $a + $b;

print $q->header("application/json");
print $json->encode({ c => $c });

    [download]

    Client

    use v5.14;
use HTTP::Tiny ();
use JSON::PP ();

my $json = 'JSON::PP'->new;
my $http = 'HTTP::Tiny'->new;
my $url  = 'http://buzzword.org.uk/2013/json-addition.cgi';

my $input    = { a => 40, b => 2 };
my @request  = ($url => { content => $json->encode($input) });
my $response = $http->post(@request);
my $output   = $json->decode($response->{content});
say $output->{c};

    [download]

    (All modules used above are part of Perl core as of 5.14+, but CGI is scheduled to leave core in a future version of Perl.)

    package Cow { use Moo; has name => (is => 'lazy', default => sub { 'Mooington' }) } say Cow->new->name
[reply]
[d/l]
[select]

      Thank you very much. I greatly appreciate it. I get the correct value returned when I use the URL http://buzzword.org.uk/2013/json-addition.cgi but I get malformed JSON string, neither array, object, number, string or atom, at er offset 0 (before "<!DOCTYPE HTML PUBLI...") at json_client.pl line 12 when I use my own URL http://myurl.com/cgi-bin/json_mode.cgi. I have installed the server in the cgi-bin directory with permission 755 and the perl has valid syntax etc. It looks as if I cannot access the cgi file in the cgi-bin directory. Do you know a way around this?

      I also see it described as text/cgi whereas some, but not all of the other cgi files are described as application/cgi. Any ideas why this is the case?

[reply]

        Have you visited http://myurl.com/cgi-bin/json_mode.cgi in your browser?

        package Cow { use Moo; has name => (is => 'lazy', default => sub { 'Mooington' }) } say Cow->new->name
[reply]
[reply]
[d/l]

In Section Seekers of Perl Wisdom