Sigh, I go away for a few weeks and see lots of solutions which don't use Text::CSV and their friends. Text::CSV can handle space or tab separated data as well as "normal" comma separated data.

Please do not succumb to the Dark Side, and use the Force of existing CPAN modules properly. :-)

use Text::CSV;

my %data;
my $csv = Text::CSV->new ( { binary => 1 } )  # should set binary attr
+ibute.
                 or die "Cannot use CSV: ".Text::CSV->error_diag ();
 
open my $fh, "<:encoding(utf8)", "test.csv" or die "test.csv: $!";
while ( my $row = $csv->getline( $fh ) ) {
     my ($key, $value) = @$row;
     $data{$key} =0 if (!exists $data{$key});
     $data{$key} |=1 if ($value == 1);
     $data{$key} |=2 if ($value == 3);

}
$csv->eof or $csv->error_diag();
close $fh;

foreach my $key (%data) {
   print "$key invalid\n" if ($data{$key} != 3);
}
[download]

I'm sure there are more elegant and probably better solutions, but this is one way to do it.

#!/usr/bin/env perl
use strict;
use warnings;

my %fields;
my $header = <DATA>;
while (<DATA>) {
    chomp;
    next if /\A\s*\Z/;
    my ($f1, $f2) = split;
    push @{ $fields{$f1} }, $f2;
}

for my $k (keys %fields) {
    my ($one, $three) = (0, 0); # if either of these remain zero, ID i
+s invalid

    for my $values ( @{ $fields{$k} } ) {
        ++$one   if ( $values == 1 );
        ++$three if ( $values == 3 );
    }

    print "invalid ID: $k\n" unless $one * $three;
}

__DATA__
field1 field2
3-2000/7.48 1
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 3

4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 3
[download]

#!/usr/bin/perl 
use strict;
use warnings;

my $fileName = $ARGV[0];

open (FILE, "<", $fileName);

my $header = <FILE>;
my @countArray = ();
my @line;
my @allTags;
my %results;
my $uniqueTag; 
my $one = "NO";
my $three = "NO";

while (<FILE>)
    {
        @line = split(" ", $_);
        $uniqueTag = $line[0] if @line > 1;
        if (@line == 2)
            {
                $three = "YES" if $line[1] == 3;
                $one = "YES" if $line[1] == 1;
            }
                
        if ((@line <2) || (eof))
            {
                if (($three eq "YES") && ($one eq "YES"))
                    {
                        $results{$uniqueTag} = "GOOD";
                    }
                    
                else
                    {
                        $results{$uniqueTag} = "BAD";
                    }
                push (@allTags, "$uniqueTag");
                $one = "NO";
                $three = "NO";
            }
    }

for (@allTags)
    {
        print STDERR "$_\t $results{$_}\n";
    }
[download]

Something like this:

use strict;
use warnings;

my %data;
<DATA>;

while(<DATA>){
  chomp;
  next if/^\s*$/;
  my ($key, $value) = split;
 push @{$data{$key}},$value; 
}

 my $counter;

 for(keys %data){
   for(@{$data{$_}}){
     ++$counter if $_ == 1 or $_ == 3;
   }
    print $_,' a good file',$/ if $counter == 2;
 }


__DATA__
field1 field2
3-2000/7.48 1
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 3

4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 3
[download]

What if there were two 1's and no 3's or vice versa. Then $counter == 2 and the file wouldn't be good.

G'day mmittiga17,

Here's my take on a solution:

#!/usr/bin/env perl -l

use strict;
use warnings;

my %good;

while (<DATA>) {
    my ($id, $flag) = split;
    next unless $id;
    ++$good{$id}[$flag];
}   

for (keys %good) {
    print if $good{$_}[1] && $good{$_}[3];
}   

__DATA__
3-2000/7.48 1
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 3

4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 3
[download]

Sample run:

$ pm_id_flag_validation.pl
3-2000/7.48
[download]

Just one more solution using the input record separator special variable ,$/. It does make a few assumption about the structure of the data though.

use strict;
use warnings;

my $header = <DATA>;
$/ = "\n\n";

while (<DATA>) {
    if (/ 1\n.* 3\n/s) {
        my $id = substr($_,0,11);
        print "good for $id\n";
    }
}

__DATA__
field1 field2
3-2000/7.48 1
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 2
3-2000/7.48 3

4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 2
4-0000/8.40 3
[download]