G'day SuzuBell,

Firstly, a few comments on your code (some of which may have already been addressed in other parts of this thread):

• In general, you should not be prefixing your subroutine calls with an '&'. In fact, I would go so far as to say don't ever do it unless you know exactly why you're doing it. See perlsub for details.
• You should not simply assume that some element of some array contains valid data. You need to test for this and code appropriate actions (which may include setting a default value or not processing that element). Not doing this is the likely cause of your "... uninitialised value ..." messages.
• You appear to have a general lack of knowledge about references. That's fine: it's just something you need to learn — try the perlreftut tutorial (perlref has more complete details).
• As you're working with complex data structures, you should look at the Perl Data Structures Cookbook. I'd recommend reading the initial sections up to CODE EXAMPLES; then, as a minimum for your current script, the ARRAYS OF ARRAYS section.
• You're limiting yourself by hard-coding array variables with numbers: consider the number of lines of code you'd have to change if you needed an @array4. You can put (anonymous) references to each array into another array which can expand or contract as required.
• You're doing lots of unnecessary processing with the continual referencing and dereferencing of your arrays. This will slow down your application and could potentially lead to memory issues. In the code I've posted below, see how I've eliminated all the additional processing associated with your two subroutine calls: secondRoutine(firstRoutine());

The code below (which includes sample input and output) shows how to create, manipulate and access the type of array data you appear to be working with. It addresses all the issues I raised. I'll leave you to adapt it to your specific requirements.

$ perl -Mstrict -Mwarnings -le '
    use constant MAX_COLUMN_INDEX => 2;

    secondRoutine(firstRoutine());

    sub firstRoutine{
        my $matrix;

        while (<>) {
            my @fields = split;

            for (0 .. MAX_COLUMN_INDEX) {
                push @{$matrix->[$_]},
                    defined $fields[$_] ? $fields[$_] : "<undef>";
            }
        }

        return $matrix;
    }

    sub secondRoutine {
        my $matrix = shift;

        for my $row (0 .. $#{$matrix->[0]}) {
            for my $col (0 .. MAX_COLUMN_INDEX) {
                print "Row $row Col $col = $matrix->[$col][$row]";
            }
        }

        return;
    }
'
q w e
a s
z
Row 0 Col 0 = q
Row 0 Col 1 = w
Row 0 Col 2 = e
Row 1 Col 0 = a
Row 1 Col 1 = s
Row 1 Col 2 = <undef>
Row 2 Col 0 = z
Row 2 Col 1 = <undef>
Row 2 Col 2 = <undef>
[download]