I had no problems with using /^/ for the beginning of a line - maybe because I processed the records line by line.

#!/usr/bin/perl
use warnings;
use strict;

$/ = "#";
while (<DATA>) {
    next if $. == 1; # Skipt the empty "first" record;

    my @lines = split /\n/;
    my ($vlan, $ifconfig) = (0, 0);

    for (@lines) {
        if (/^hostname/) {
            print "$_\n";

        } elsif (/^vlan/) {
            $vlan++ for m/\S+/g;
            $vlan -= 3;

        } elsif (/^ifconfig/) {
            $ifconfig++ for m/\S+/g;
            $ifconfig -= 3;
        }
    }
    print "vlan $vlan\nifconfig $ifconfig\n";
    print "WRONG!!!\n" if $vlan != $ifconfig;
}
[download]

With my code I was able output such as:

$ ./vlan.pl
This is element : 0
This is element : 1
This is element : 2
This is element : 3
found a vlan line
found an ifconfig line
This is element : 4
found a vlan line
found an ifconfig line
[download]

Using choroba's code I had to change 1 thing, probably because I'm horrible at communicating :) I just commented out what to match on the ifconfig line

 } elsif (/^ifconfig/) {
            $ifconfig++ #for m/\S+/g;
        }
[download]

because here I just want to count the lines themselves until we run out of ifconfig lines, not the number of words on each line like in the vlan example, then compare that with how many vifs we counted.

At first I was getting this:

hostname host97
vlan 72
ifconfig 504
WRONG!!!
[download]

But now I get this:

hostname host97
vlan 72
ifconfig 72
[download]

Guess I was overcomplicating it by reading it into an array and then trying to iterate an array since I already have the data preformatted (from another script) when I opened the filehandle in this one. That too can be cleaner, but this is functional and that is what matters until we learn more!

Thank you choroba! this gives me other ideas on other little things like this I'm trying to do!

G'day randompug,

Welcome to the monastery.

Here's a way to do this that doesn't involve slurp mode or any regexes:

$ perl -Mstrict -Mwarnings -E '
    my @data = (
        "# hostname 123",
        "hostname 123",
        "vlan create vif1 1 2 3 4 5 6",
        "vlan add vif1 7 8 ",
        "ifconfig vif1-1 some data here",
        "ifconfig vif1-2 some data here",
        "..",
        "ifconfig vif1-9 some data here",
        "# hostname 456",
        "hostname 456",
        "vlan create vif5 1 2",
        "vlan add vif5 3 4 5",
        "vlan add vif5 6 7 8 9",
        "ifconfig vif5-1 some data here",
        "ifconfig vif5-2 some data here",
        "..",
        "ifconifg vif5-9 some data here",
    );

    my ($hostname, @hosts, %host_data);

    for (@data) {
        my @fields = split;

        if ($fields[0] eq "hostname") {
            push @hosts => ($hostname = $fields[1]);
        }
        elsif ($fields[0] eq "vlan") {
            $host_data{$hostname}{vlan} += @fields - 3;
        }
        elsif ($fields[0] eq "ifconfig") {
            ++$host_data{$hostname}{ifconfig};
        }
    }

    for (@hosts) {
        say "Hostname: $_";
        say "vlans: $host_data{$_}{vlan}";
        say "ifconfigs: $host_data{$_}{ifconfig}";
    }
'
Hostname: 123
vlans: 8
ifconfigs: 3
Hostname: 456
vlans: 9
ifconfigs: 2
[download]

I don't know where your real data is coming from: you should be able to just change "for (@data) {" to "while (<$file_handle>) {" (or whatever's appropriate) and get the same results. I'll leave you to check the vlan/ifconfig count. Your one instance of ifconifg may be intended for testing or perhaps just a typo.

IMHO the best data structure is an array of hashes. Each time you encounter a hostname line, you push a new hash onto the array and store the hostname. For each of the following lines you can refer to that hash by $array[-1] until the next hostname line. See below:

use strict;
use warnings;

my @results;
while(<DATA>){
  push @results, {'hostname' => $1}         if /^(hostname.*)/; # push
+ a new hash into the array
  $results[-1]->{'vlan'}+= split(/\s+/) - 3 if /^vlan/;         # numb
+er of words - 3
  $results[-1]->{'ifconfig'}++              if /^ifconfig/;     # one 
+for each ifconfig
}

for( @results ) {
  print "Hostname :  $_->{'hostname'}\n";
  print "# of vlans: $_->{'vlan'}\n";
  print "# of ifconfig lines: $_->{'ifconfig'}\n\n";
}

__DATA__
# hostname 123
hostname 123
vlan create vif1 1 2 3 4 5 6
vlan add vif1 7 8 
ifconfig vif1-1 some data here
ifconfig vif1-2 some data here
ifconfig vif1-9 some data here
# hostname 456
hostname 456
vlan create vif5 1 2
vlan add vif5 3 4 5
vlan add vif5 6 7 8 9
ifconfig vif5-1 some data here
ifconfig vif5-2 some data here
ifconfig vif5-9 some data here
[download]

the split function requires a regex.

I agree that it is usually better practice to use a regex as a split pattern (and I have upvoted this post, contrary to the majority of viewers as of this writing), because split is really geared on using regex patterns (IMHO), but saying that it requires a regex is somewhat of an exageration: it can work with other expressions like a single character or even a string. Although, with a string, the results can sometimes be sometimes somewhat unexpected when the string contains wierd characters... But using a single character such as '#', as done by the OP, does work fine:

  DB<1> $c = "jdskq#jdskl"

  DB<2> @d = split '#', $c;

  DB<3> x @d
0  'jdskq'
1  'jdskl'
[download]

blah blah blah

split demands a regex, it doesn't accept strings, it takes patterns, doesn't matter how you quote '#' its a regex pattern

the split function requires a regex.

A string is also a regex, if not a very interesting one.

-QM
--
Quantum Mechanics: The dreams stuff is made of