G'day AmnonM,

Welcome to the monastery.

If you decrement the 'n' value, you can do this:

s/(.)\1{$n}/$1 x $m/eg;
[download]

Here's my test:

$ perl -Mstrict -Mwarnings -E '
    sub mod_char_count {
        my ($n, $m, $x) = @{+shift};
        --$n;
        $x =~ s/(.)\1{$n}/$1 x $m/eg;
        return $x;
    }

    my @data = (
        [4, 1, "p8888er9999l"],
        [1, 3, "monks"],
    );

    say mod_char_count($_) for @data;
'
p8er9l
mmmooonnnkkksss
[download]

Thanks to all. I'll try these implementations.

The below relies on embedding Perl code in the substitution portion of the regex (/e) and could also be a little more terse if you can guarantee a newer version of Perl, where the /r parameter of regex is available.

sub translate
{
    my ($n, $m, $_) = @_;
    $n--;
    s/(\w)\1{$n}/$1 x $m/ge;
    $_;
}

print translate(4,1,'p8888er9999l');   # -> p8er9l
print translate(1,3,'monks');          # -> mmmooonnnkkksss
[download]

$ perl -le'
my $n = 4;
my $m = 1;
$_ = "p8888er9999l";
print;
s/((.)\2*)/ $n == length $1 ? $2 x $m : $1 /eg;
print;
'
p8888er9999l
p8er9l

$ perl -le'
my $n = 1;
my $m = 3;
$_ = "monks";
print;
s/((.)\2*)/ $n == length $1 ? $2 x $m : $1 /eg;
print;
'
monks
mmmooonnnkkksss
[download]

The (.){$n} construct will match any sequence of $n characters, not just repeating characters.