open

To understand why you need to escape backslashes, please read the documentation on string "interpolation".

Basically, if you use double-quotes ("), the backslash(\) is the escape character. If you want to use that in the string, it needs to be doubled up.

"C:\\windows\\file.txt"
[download]

As you become more familiar with perl, you will understand the reasons to write "open" in the following form:

my $filename="C:\\windows\\file.txt" ; ## or "C:/windows/file.txt" 

open (my $fh, "<", $filename) or die "Could not open $filename: $!";
[download]

while (<$fh>){
  # Process the contents of the record
  # which is stored in $_
}

close $fh or warn "Could not close $filename:$!";
[download]

G'day virtuemart2,

Welcome to the monastery.

You've got a few issues with that. Firstly, you can test that string yourself:

$ perl -Mstrict -Mwarnings -le 'print "C:\windows\file.txt"'
Unrecognized escape \w passed through at -e line 1.
C:windows
         ile.txt
[download]

Obviously, that's not good. Note that -Mwarnings (on the command line) is the same as use warnings; (in a script). When it's used, Perl tells you what's wrong; when you don't use it, you just see strange output without any explanation:

$ perl -Mstrict -le 'print "C:\windows\file.txt"'
C:windows
         ile.txt
[download]

See warnings: it's your friend. Also note -Mstrict (as I have here, on the command line) is the same as use strict; (in a script). See strict: it, too, is your friend.

If you're stuck with a situation where you need double-quotes, you must escape (prefix with a backslash) each backslash, i.e. write "\\" wherever you had "\":

$ perl -Mstrict -Mwarnings -le 'print "C:\\windows\\file.txt"'
C:\windows\file.txt
[download]

That looks rather messy, and would be even messier with a long pathname. The best thing to avoid this, is to use single-quotes, i.e. 'C:\windows\file.txt'. I can't actually show that on the command line because I'm already using single-quotes; however, '...' is the same as q{...}, so:

$ perl -Mstrict -Mwarnings -le 'print q{C:\windows\file.txt}'
C:\windows\file.txt
[download]

And, just for completeness, "..." is the same as qq{...}:

$ perl -Mstrict -Mwarnings -le 'print qq{C:\windows\file.txt}'
Unrecognized escape \w passed through at -e line 1.
C:windows
         ile.txt
[download]

Although, I've used braces ({...}) to delimit the string, you can use other characters: matchingleft-right pairs such as q[...] and q(...), and non-matchingidentical pairs such as q/.../ and q|...|. This is explained in perlop: Quote and Quote-like Operators, with further details in perlop: Quote-Like Operators. [Yes, those two section headings are somewhat confusing — I didn't write them. :-) ]

That's strings sorted out. The next problem is open fh $PATH. Assuming you'd given $PATH a value, you'd get this somewhat cryptic message:

$ perl -Mstrict -Mwarnings -e 'my $PATH = q{not_a_file}; open fh $PATH
+'
Can't locate object method "fh" via package "not_a_file" (perhaps you 
+forgot to load "not_a_file"?) at -e line 1.
[download]

The problem is that you've used incorrect syntax for the open function. You could just make a minor change to fix the syntax; however, it would be much better if you wrote that like this:

open my $fh, '<', $path or die "Can't open $path: $!";
[download]

See open for a detailed explanation. Also look at die; and you'll find $! explained in perlvar.

Putting all of that together:

# Uncomment ONLY ONE of these:
#my $path = 'C:\windows\path\to\filename';
#my $path = '/linux/path/to/filename';

# Now open your chosen file for reading:
open my $fh, '<', $path or die "Can't open $path: $!";
[download]

Finally, have a look at perlrun, so you can run those sorts of tests for yourself; and, I suspect, you'd benefit greatly from reading "perlintro -- a brief introduction and overview of Perl".

open fh, 'C:\windows\file.txt';
[download]

Note that using lowercase barewords for filehandles begs for troubles. It is safer to use lexical filehandles, 3-argument form of open, and also check the return value of open in case the opening did not succeed:

open my $FH, '<', 'C:\windows\file.txt' or die $!;
[download]

See open for details.

In general, I would recommend using the forward
slash instead of the "back slash".

open fh $PATH;

As a brief additional comment to the clear and complete answer made by NetWallah, the line quoted above does not make any sense since $PATH has not been initialized and/or declared anywhere. I am not sure what your intention is with it, but it can be removed altogether.