Join and Concatenation

roho has asked for the wisdom of the Perl Monks concerning the following question:

I found out (much to my surprise) that join MUST enclose its arguments in parens if it is used in a statement with concatenations. Is this normal behavior for join, or is this a bug? The sample code below shows the effect:

#!/usr/bin/perl
use strict;
use warnings;

my @array = qw( a b c );

print "\nSimple join (without parens) - OK\n";
my $cols  = join('],[',@array);
print "cols = $cols\n";

print "\nConcatenation and join (without parens)- NOT OK\n";
$cols  = '[' . join '],[',@array . ']';
print "cols = $cols\n";

print "\nConcatenation and join (with parens) - OK\n";
$cols  = '[' . join('],[',@array) . ']';
print "cols = $cols\n";
[download]

"Its not how hard you work, its how much you get done."

Comment on Join and Concatenation Download Code

Replies are listed 'Best First'.
Re: Join and Concatenation by toolic (Bishop) on Sep 13, 2013 at 18:03 UTC
I don't think this is a join bug. I think it is a matter of operator precedence (see perlop). I think the concatenation operator is enforcing scalar context on the array (hence the 3). Tip #6 from the Basic debugging checklist (B::Deparse). Look how perl internally places parens: `print "\nConcatenation and join (without parens)- NOT OK\n"; $cols = '[' . join('],[', @array . ']');` [download] If your goal is to enclose all elements of an array with square brackets, then join them with commas, I think a more natural approach uses map: `$cols = join ',', map { "[$_]" } @array;` [download]	[reply] [d/l] [select]
Re: Join and Concatenation by LanX (Saint) on Sep 13, 2013 at 18:31 UTC
it's b/c concat has higher operator precedence, using B::Deparse reveals it `DB<234> dp $cols = '[' . join '],[',@array . ']'; { ($cols = ('[' . join('],[', (@array . ']')))); }` [download] Cheers Rolf ( addicted to the Perl Programming Language)	[reply] [d/l]
Re: Join and Concatenation by ricDeez (Scribe) on Sep 14, 2013 at 00:53 UTC
As has already been stated this is related to operator precedence, with the parenthesis forcing order and returning the results you want. However you can avoid using join altogether if you modify the $" internal variable. In my opinion, this is cleaner and even obviates the need for an intermediate variable. This is what I am thinking: `#!/usr/bin/perl use strict; use warnings; my @array = qw( a b c ); { local $" = '],['; print "[@array]\n"; }` [download]	[reply] [d/l]