The regex only works if the hash contains cat and dog in the same value, but judging from the description, that's not what you want.

Instead of trying to be too clever, I'd use something like this:

use 5.014;
use warnings;

my @hashes = (
    { bla => 'cat', blubb => 'dog' },
    { only => 'cat' },
    { just => 'dog' },
);

sub hr_contains_cat_and_dog {
    my $hr = shift;
    my ($has_cat, $has_dog);
    for (values %$hr) {
        $has_cat = 1 if /cat/i;
        $has_dog = 1 if /dog/i;
    }
    return $has_cat && $has_dog;
}

my @result = grep hr_contains_cat_and_dog($_), @hashes;

use Data::Dumper;
print Dumper \@result;
__END__
$VAR1 = [
          {
            'bla' => 'cat',
            'blubb' => 'dog'
          }
        ];
[download]

G'day walkingthecow,

Your posted solution seems overly complicated. Some test data would have been useful. Here's how I might have tackled this:

$ perl -Mstrict -Mwarnings -e '
    use List::MoreUtils qw{uniq};
    use Data::Dumper;

    my @pets = (
        { a => "cat", b => "dog" },
        { c => "dog", d => "cat" },
        { e => "dog" },
        { f => "cat" },
        { g => "goldfish" },
        { h => "cat", i => "cat" },
        { j => "cat", k => "cat", l => "dog", m => "dog" },
    );

    my @cat_and_dog;

    for (@pets) {
        push @cat_and_dog, $_ if 2 == grep { /^(?:cat|dog)$/ } uniq va
+lues %$_;
    }

    print Dumper \@cat_and_dog;
'
$VAR1 = [
          {
            'b' => 'dog',
            'a' => 'cat'
          },
          {
            'd' => 'cat',
            'c' => 'dog'
          },
          {
            'j' => 'cat',
            'k' => 'cat',
            'l' => 'dog',
            'm' => 'dog'
          }
        ];
[download]

Some more test cases to consider:

    { m => 'catdog' },
    { n => 'cat pics', o => 'cat', p => 'doggy' },
[download]

Both aren't included in your result list; might be interesting to know if they should.

Perl 6 - the future is here, just unevenly distributed

Yes, I had considered adding other test data: "cats", "dogs", "catalogue", "raining cats and dogs", etc. I wasn't really sure what walkingthecow wanted, which prompted the "Some test data would have been useful." comment.

-- Ken

 my @found= grep { my %r =  reverse %$_; exists $r{cat} && exists $r{d
+og}}   @pets;
[download]

It really depends on whether walkingthecow wants a case insensitive substring search, as his own code implies, or a an exact, case sensitive match as your code does.

Perl 6 - the future is here, just unevenly distributed

It's easy enough to add case insensitivity to NetWallah's code with fc or lc.

For v5.16 or newer:

use v5.16;
...
my @found= grep { my %r =  reverse map fc, %$_;
                  exists $r{cat} && exists $r{dog} } @pets;
[download]

For older versions as well:

my @found= grep { my %r =  reverse map lc, %$_;
                  exists $r{cat} && exists $r{dog} } @pets;
[download]

Hmm - I did not notice any hints of requiring case-insensitivity, but in any case, that requirement is easily accommodated in my code by adding a "map {lc}" .

 my @found= grep { my %r = map{lc} reverse %$_; exists $r{cat} && exis
+ts $r{dog}} @pets;
[download]

             My goal ... to kill off the slow brain cells that are holding me back from synergizing my knowledge of vertically integrated mobile platforms in local cloud-based content management system datafication.