Hi,

please take this as a starting point:

#!/usr/bin/env perl
use strict;
use warnings;

my $line = <STDIN>;
my $day;
my $month;
my $year;

chomp($line);
if($line =~ /^([0-3][0-9])-([01][0-9])-([0-9]{4})$/) {
    $day = $1;
    $month = $2;
    $year = $3;
}
else {
    die "ERROR: Wrong date format, please provide DD-MM-YYYY: $line";
}
print "Date is: $year-$month-$day\n";
[download]

You have to add code to check whether the date is a valid date.

McA

AshleyJordan:

You can't format STDIN, you can only look at what came in and see if it matches what you want. You can do it something like this:

# Get a line from the user (or file if redirected)
my $line = <STDIN>;
while ($line !~ /regex to check input/) {
    # input didn't match regex, so tell the user and get another line 
+of data
    print "Sorry, I don't understand that, please enter the date like:
+ DD-MM-YYYY\n";
    $line = <STDIN>;
}
... code that uses properly formatted date ...
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

G'day Ashley,

Welcome to the monastery.

You were sort of on the right track with capturing the elements of the date with "(\d{n})" constructs, but you appear to have thought that including variables within the regex would somehow assign to them. For starters, I'd recommend you look at "perlintro -- a brief introduction and overview of Perl" and "perlretut - Perl regular expressions tutorial".

If all you want to do is check the format and, if OK, build $sql, you can code this:

#!/usr/bin/env perl -l

use strict;
use warnings;

while (<STDIN>) {
    chomp;

    if (/^(\d{2})-(\d{2})-(\d{4})$/) {
        print "... day='$1' month='$2' year='$3' ...";
    }
    else {
        print 'Not DD-MM-YYYY format';
    }
}
[download]

Here's a sample run:

$ pm_parse_stdin.pl
19-9-2013
Not DD-MM-YYYY format
19/9/2013
Not DD-MM-YYYY format
30-02-2013
... day='30' month='02' year='2013' ...
99-99-9999
... day='99' month='99' year='9999' ...
19-09-2013
... day='19' month='09' year='2013' ...
19-09-20133
Not DD-MM-YYYY format
[download]

That's correctly weeding out "19-9-2013" and "19/9/2013"; unfortunately, it's quite happy with possible typos like "30-02-2013" and completely bogus dates like "99-99-9999". So, you'll probably need to assign the captured values to variables and then validate them. There's lots of ways of doing this, and it may well depend on what sort of feedback you want to present to your users; here's a fairly straightforward method, using the builtin module Time::Piece, that differentiates between bad format, possible typo or leap year error, and completely nonsense dates:

#!/usr/bin/env perl -l

use strict;
use warnings;

use Time::Piece;

while (<STDIN>) {
    chomp;

    if (/^(\d{2})-(\d{2})-(\d{4})$/) {
        my ($day, $month, $year) = ($1, $2, $3);

        my $tp = eval { Time::Piece->strptime("$day$month$year", '%d%m
+%Y') };

        if (defined $tp) {
            if ($tp->ymd eq "$year-$month-$day") {
                print "... day='$day' month='$month' year='$year' ..."
+;
            }
            else {
                print "INVALID DATE: $day-$month-$year";
            }
        }
        else {
            print "BOGUS DATE: $day-$month-$year";
        }
    }
    else {
        print 'Not DD-MM-YYYY format';
    }
}
[download]

Sample run:

$ pm_parse_stdin_2.pl
19-9-2013
Not DD-MM-YYYY format
19/09/2013
Not DD-MM-YYYY format
19-09-2013
... day='19' month='09' year='2013' ...
99-99-9999
BOGUS DATE: 99-99-9999
32-02-2013
BOGUS DATE: 32-02-2013
31-02-2013
INVALID DATE: 31-02-2013
29-02-2013
INVALID DATE: 29-02-2013
29-02-2012
... day='29' month='02' year='2012' ...
19-09-20133
Not DD-MM-YYYY format
[download]

Here is what I use to handle the most common date formats (assume the usual use strict; and use warnings; as well as use Carp; and use DateTime; are present):

# Utility function to convert a date string to a DT object
sub _str2dt {
    # string that is supposed to be yyyy-mm-dd or mm/dd/yyyy
    # single digit months/days are allowed with this.
    my $date = shift;

    # convert date param to DT object
    my ($y,$m,$d);
    if ( $date =~ m/(^\d{4})\-(\d{1,2})\-(\d{1,2})($|\D+)/ ) {
        $y = $1, $m = $2, $d = $3;
    } elsif ( $date =~ m/^(\d{1,2})\/(\d{1,2})\/(\d{4})($|\D+)/ ) {
        $y = $3, $m = $1, $d = $2;
    } else {
        croak "Unable to parse date string: $date";
    }
    eval { $date = DateTime->new( year => $y, month => $m, day => $d )
+; }
        or croak "Invalid date: $date";

    return $date;
}
[download]