Fortunately, Perl will convert your string back to a number whenever you treat it as one.
like say $stuff + 0 ; # print $stuff + 0 , "\n" ; # on older perl versions.

I also believe Data::Dumper did not convert your number to a string but added quotes for clarity.

Cheers, Sören

I also believe Data::Dumper did not convert your number to a string but added quotes for clarity.

Yep, it simply quoted the strings -- a string is not a number until its treated like a number :)

$ perl -MData::Dump -e " dd '+11', 0+ '+11' "
("+11", 11)
[download]

Hi there, thank you. While treating the output as number so eg:

#!/usr/bin/perl -w
use strict;

my $resultnow='C:/Users/user/Desktop/solution.dat';

open (FILE, '<', $resultnow) or die "$resultnow File not found : $!";
my @lines = <FILE>;

my $valuenow= $lines[9];

my @items=split' ',$valuenow;



use Data::Dumper;



#print Dumper(@items);
my $val=Dumper("$items[-1]");


my $n= "$val+8";
print $n;

close (FILE);
[download]

here I tryed to make a sum. with "my $n= "$val+8";", so that I can obtain a vlue like -31.9999400000 (instead of '-39.9999400000'+8). But unfortunately that does not work. So how can I solve this problem? (that was the reason why I thought it is a string value).

G'day semipro,

You really need to show your code (i.e. how you're using the value in a calculation), the output you get as well as any error or warning messages (these need to be exactly as you see them and marked up within <code>...</code> tags). Please read the "How do I post a question effectively?" guidelines for full details regarding this.

I suspect the message you're getting is something like:

Argument "$VAR1 = '-39.99994';\n" isn't numeric ...
[download]

The part that isn't numeric is:

$VAR1 = '-39.99994';\n
[download]

This is the string that Dumper($items[-1]) would be returning: '-39.99994' is just part of that string.

I think you should spend some time reading the Data::Dumper documentation. I suspect you haven't quite understood what it does. A more usual usage would be something like:

print Dumper \%some_hash;
[download]

There'll be many examples in the monastery (use Super Search). Here's a couple from recent nodes I've written: hashref data structure dump and arrayref data structure dump.

Perl will happily convert numbers between string and numeric contexts. For example, this code:

#!/usr/bin/env perl -l

use strict;
use warnings;

my $val = '-39.9999400000';
print $val;
print 2.5 * $val;

my $val2 = -39.9999400000;
print $val2;
print "Number in a string >>> $val2 <<<";
[download]

produces this output:

-39.9999400000
-99.99985
-39.99994
Number in a string >>> -39.99994 <<<
[download]

You'll notice that trailing zeros were truncated. You can control the format with sprintf.

You can also force the context yourself: 0+$x (numeric); ''.$x (string); !!$x (boolean).

Just to add to kcott’s excellent answer:

If you have a string like "$VAR1 = '-39.9999400000';\n" and want to get the number inside, you can either eval the string and use $VAR1, or else extract the number with a regular expression:

#! perl
use strict;
use warnings;
use Data::Dumper;

      my @lines  = <DATA>;
chomp(my $line   = $lines[0]);
chomp(my $string = Dumper("$line"));

print "Dumper returns the string \"$string\"\n";

# Method 1: eval the string

my    $VAR1;
eval  $string;      # Sets $VAR1
my    $m = $VAR1 + 8;
print "Method 1: $m\n";

# Method 2: extract the number

if ($string =~ /'([-0-9.]+)'/)
{
    my    $value = $1;
    my    $n     = $value + 8;
    print "Method 2: $n\n";
}

__DATA__
-39.9999400000
[download]

Output:

23:27 >perl 730_SoPW.pl
Dumper returns the string "$VAR1 = '-39.9999400000';"
Method 1: -31.99994
Method 2: -31.99994

23:27 >
[download]

See chomp, eval, and perlretut.

Hope that helps,

yeah, see Re: Incrementing "Infinity" bug (numification, perlnumber, magic increment decrement), perlnumber, perldata, Infinity and Inf?, atoi, atof, strtod, Is this odd behavior a floating point problem?, What Every Programmer Should Know About Floating-Point Arithmetic or Why don’t my numbers add up?