G'day ag88,

Welcome to the monastery.

You can treat each BLASTP block as a single record. This makes it easy to identify which have "0 hits found", and print their "gi" values. (In the code below, I've truncated the data lines to 60 characters.)

#!/usr/bin/env perl -l

use strict;
use warnings;

{
    local $/ = "# BLASTP 2.2.28+\n";

    while (<DATA>) {
        print /gi\|(\d+)/ if /0 hits found/;
    }
}

__DATA__
# BLASTP 2.2.28+
# Query: gi|338220664|gb|EGP06123.1| hypothetical protein GE
# Database: nr-25sep
# Fields: query id, subject id, % identity, alignment length
# 2 hits found
gi|338220664|gb|EGP06123.1| gi|45383702|ref|NP_989542.1|    
gi|338220664|gb|EGP06123.1| gi|15419940|gb|AAK97214.1|  44.1
# BLASTP 2.2.28+
# Query: gi|338220666|gb|EGP06125.1| hypothetical protein GE
# Database: nr-25sep
# 0 hits found
# BLASTP 2.2.28+
# Query: gi|338220651|gb|EGP06111.1| hypothetical protein GE
# Database: nr-25sep
# 0 hits found
[download]

Output:

338220666
338220651
[download]

See "perlvar: Variables related to filehandles" for a discussion of this usage of "$/" (the input record separator).

sub getGI
{
my $previous1,$previous2;
open(FILE, "twentySeq1e-10.out") or die("Cannot open file");
while(<FILE>)
{
my $line = $_;

if($line=~/# 0 hits found/)
{
print "$previous2\n";
}
$previous2= $previous1;
$previous1= $line;
}
[download]

The generalized solution would use an array. You use unshift() to add the line at the start of the array and you use pop() to remove the last line if the array has length n+1 (with n being the number of lines you want to remember). That is called a pipeline, queue, shift register or FIFO (first-in-first-out).

Thankyou soo much for help it worked. Thanks alot :)

Hi,

in this case I would take the following approach:

#!/usr/bin/env perl
use strict;
use warnings;

use 5.010;

# read first line assuming it is a kind of block seperator
my $bsep = <>;

$/ = $bsep;
while(defined(my $block = <>)) {
    chomp $block;
    my @records = split /\n/, $block;
    next if @records < 3; # malformed block
    foreach my $record (@records) {
        say $record;
    }
    say "========================";
}
[download]

Now you can find and operate on every block how you like.

Best regards
McA

This is not an uncommon task. Here is one possible solution which you can alter to suit your particular requirements.

I want to get a line previous to a previous line. In short words 2nd previous line to a matching line.

yes, the answer is the same

Try this it works for me.

#!/usr/bin/perl -w

use strict;
use warnings;
#open(FILE, "twentySeq1e-10.out") or die("Cannot open file");
my $gi;
while(<DATA>){
    if(/^# Query: gi.([0-9]+)/) {$gi = $1;} 
    if(/^# 0 hits found/){print "$gi\n";}
}
__DATA__
# BLASTP 2.2.28+
# Query: gi|338220664|gb|EGP06123.1| hypothetical protein GEW_00005 [P
+asteurella multocida subsp. gallicida str. Anand1_poultry]
# Database: nr-25sep
# Fields: query id, subject id, % identity, alignment length, mismatch
+es, gap opens, q. start, q. end, s. start, s. end, evalue, bit score
# 2 hits found
gi|338220664|gb|EGP06123.1|    gi|45383702|ref|NP_989542.1|    45.15  
+  206    96    7    3    204    28    220    1e-51     170
gi|338220664|gb|EGP06123.1|    gi|15419940|gb|AAK97214.1|    44.17    
+206    98    7    3    204    28    220    5e-50     166
# BLASTP 2.2.28+
# Query: gi|338220666|gb|EGP06125.1| hypothetical protein GEW_00015 [P
+asteurella multocida subsp. gallicida str. Anand1_poultry]
# Database: nr-25sep
# 0 hits found
# BLASTP 2.2.28+
# Query: gi|338220651|gb|EGP06111.1| hypothetical protein GEW_00275 [P
+asteurella multocida subsp. gallicida str. Anand1_poultry]
# Database: nr-25sep
# 0 hits found
[download]

RESULT

Process started >>>
338220666
338220651
<<< Process finished. (Exit code 0)
[download]

• You're going through the file a line at a time.
• If you see a line you might want (a "Query" line), you save it in a variable and keep reading lines.
• If you see a "hits" line that matches your criterion, the line you saved was one you want. Print it or stick it in an array for later, or...
• If you see a "hits" line and it doesn't match your criterion, then you don't want the "Query" you saw previously. Throw it away by setting the variable to "".

Thankyou all for the suggestions. It was really helpful. The following code did my task

sub getGiForZeroHits
{
my $previous1,$previous2;
open(FILEOUT,">giForZeroHits.txt") or die("Cannot open file");
{
open(FILE, "$inputSeqFileForBlast-1e-10.out") or die("Cannot open file
+");
{
while(<FILE>)
{
my $line = $_;
if($line=~/# 0 hits found/)
{
my @lineSpl = split(/\|/, $previous2);
print FILEOUT "$lineSpl[1]\n";
} #close if

$previous2= $previous1;
$previous1= $line;
} #close while
close(FILE);
} #close FILE
close(FILEOUT)
} #close FILEOUT
} #close sub
[download]