drmrgd has asked for the wisdom of the Perl Monks concerning the following question:

Just playing around a bit with some text and grep and running into a problem I can't understand. Hoping one of you can enlighten me to what I'm overlooking.

Given two arrays with elements that consist of 3 space delimited characters, I want to print out any elements from array two for which the first two characters match an element from array 1. If I use grep in a scalar context, I can get it to work:

my @data1 = ( "a 1 a", "a 2 T", "a 3 C" );
my @data2 = ( "a 2 Y", "a 3 R", "a 4 Q", "b 5 R" );

for ( @data2 ) {
    my ($match) = $_ =~ /^(\w\s+\d)/;
    if ( grep { /$match/ } @data1 ) {
            print  "$_\n";
    }
}

[download]
This correctly prints the result: 
$ perl compare.pl
a 2 Y
a 3 R

[download]

However, if I try to use grep in a list context, storing the matches in '@result', I only get the second match and not the first:

my @results;
for my $elem ( @data1 ) {
    my ($match) = $elem =~ /(\w\s+\d)/;
    @results = grep { /$match/ } @data2;
}
 print "$_\n" for @results;

[download]
$ perl compare.pl
a 3 R

[download]

What am I missing here? Why are both matches not being stored in @results?

Replies are listed 'Best First'.
Re: Help understand why this grep does not work
by choroba (Cardinal) on Nov 02, 2013 at 15:42 UTC
    You are overwriting @results: 
    @results = grep { /$match/ } @data2;

    [download]

    To add a new value (or values) to an array, use push: 

    push @results, grep { /$match/ } @data2;

    [download]
    لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ
[reply]
[d/l]
[select]
Re: Help understand why this grep does not work
by LanX (Saint) on Nov 02, 2013 at 15:42 UTC
    you are overwriting @results in each loop and are only getting the last hits.

    edit

    better try something like push @results, grep {/$match/} @data2;

    Cheers Rolf

    ( addicted to the Perl Programming Language)

[reply]
[d/l]
Re: Help understand why this grep does not work
by drmrgd (Beadle) on Nov 02, 2013 at 15:47 UTC
    Oh my! What a dumb mistake! Thank you both for pointing that out. I can't believe I missed something so obvious!
[reply]
      if speed matters you should better consider something like building a hash for array2 for simple lookups or at least a complex OR-ed regex looping just once over array2.

      edit
        DB<102> @data1 = ( "a 1 a", "a 2 T", "a 3 C" );
 => ("a 1 a", "a 2 T", "a 3 C")

  DB<103> @data2 = ( "a 2 Y", "a 3 R", "a 4 Q", "b 5 R" );
 => ("a 2 Y", "a 3 R", "a 4 Q", "b 5 R")

  DB<104> $regex = join "|" , map {/^(\w\s+\d)/} @data1
 => "a 1|a 2|a 3"

  DB<105> grep { /^($regex)/ } @data2
 => ("a 2 Y", "a 3 R")

      [download]

      think I spotted (and corrected) a bug in your logic, you forgot to anchor to string start '^' in your grep regex.

      Cheers Rolf

      ( addicted to the Perl Programming Language)

[reply]
[d/l]
        I wondered about building a hash for this. What would be the best way? Are you thinking something like this is better: 
        my %data_hash = map { /(\w\s+\d)/ => $_ } @data2;

for my $key ( %data_hash ) {
    print "$data_hash{$key}\n" if grep { /^$key/ } @data1;
}

        [download]

        I also wondered about anchoring that match. In earlier versions, I did anchor it. But, I wasn't sure if it was necessary given the data set. I think I'll add it back as it's probably safer.

        Thanks for the advice!

[reply]
[d/l]

Back to Seekers of Perl Wisdom