Provided that your data is "not too large", Tie::File allows you to treat a file like an array.

Removing a line would then be mostly a judicious application of splice to that array.

perl -i.orig -ne 'print unless /^lb348,/' test.txt
[download]

If you're sysadmining, slinging files around as quick as you can, learning to use the command line will save you time.

Ea, thanks very much for your code, it works. However, I have to make a script, not command line statement. And I done this:

#!/usr/bin/perl -w
 open( FILE, "<", "test.txt") or die "cannot open > test.txt: $!";
while (<FILE>)
{
@array = <FILE>;
@a = grep (/^lb348,/, @array);
close FILE;
print $a;
}
[download]

But it does not work. Sorry, I am new to programming.

This:

while (<FILE>)
{
@array = <FILE>;
[download]

is just wrong. Either you read the file line by line with a while loop, or you "slurp" it into an array, but don't do both. The you are constructing a @a array and print $a, a scalar variable. The following pragmas:

use strict;
use warnings;
[download]

would have picked up these errors.

I've been writing Perl for 17 years and I'm still learning new and better ways to write code. Here's another way based on kcott's excellent answer below.

#!/usr/bin/perl -w

use strict;
use autodie;

my ($user_file, $changed_file) = qw{test.txt test.txt.mod};

open my $in_fh, '<', $user_file;
open my $out_fh, '>', $changed_file;

print "Which user? ";
my $user = <STDIN>;
chomp $user;

print $out_fh grep !/^$user,/, <$in_fh>;
[download]

This one slurps the whole file with the angle brackets, passes it through grep to filter the output which gets printed to the output file. Note the exclamation mark in front of the regex. It's the "not" operator which says you don't want the matching lines in your output.

Keep working at it. From the long list of replies, you've certainly piqued the Monks' interest.

Sometimes I can think of 6 impossible LDAP attributes before breakfast.

Well I managed to do this. The code returns every line except the one that the user wants to delete entering first username. However, if in my test.txt file two usernames start with the same letter (for example, la123 and lv444), the program will remove both lines, regardless user input that is for example la123.

$file = "test.txt";

print "Enter the username you want to remove from the information.txt 
+file\n";
$user = <STDIN>;

 open( FILE, $file) or die "cannot open > test.txt: $!";
while (<FILE>)
{
chomp;
@array = <FILE>;

@a = grep (!/^[$user]/, @array);

print @a;

}
[download]

G'day brianMonk,

Welcome to the monastery.

Here's another way to do it. While this is a working script, it's really just skeleton code. You may want to add feedback about whether the supplied username was found as well as a confirmation of the deletion.

#!/usr/bin/env perl

use strict;
use warnings;
use autodie;

my ($user_file, $changed_file) = qw{test.txt test.txt.mod};

open my $in_fh, '<', $user_file;
open my $out_fh, '>', $changed_file;

print 'Enter user to delete: ';
chomp(my $user = <>);

while (<$in_fh>) {
    print $out_fh $_ unless /^\Q$user\E,/;
}

close $in_fh;
close $out_fh;
rename $changed_file, $user_file;
[download]

#!/usr/bin/env perl
use strict;
use warnings;
use Text::CSV;
use Data::Dumper;


my $file="test.txt";
my $csv = Text::CSV->new({binary => 1,allow_whitespace => 1});

open my $fh, "<:encoding(utf8)", $file or die "Could not open $file: $
+!\n";
my @rows;
while (my $row = $csv->getline($fh)) {
      push @rows,$row;
}

my $user_to_delete = shift;

if ($user_to_delete) {
   @rows = grep { $_->[0] !~ /$user_to_delete/ } @rows;
   print Dumper @rows; 
} else {
   die "No user entered\n";
}
[download]

Hi BrianMonk,

If you will be parsing CSV files, using Text::CSV is a good idea. It handles fields where there may be a comma in the data and other good things I'm sure.

Would chomp help you here? It will happily consume/read your file on a line-by-line basis, thereby allowing you to run a RE (regex) comprised of your users input against your file.

That's probably how I'd approach it, anyway. :)

HTH, and best wishes.

--Chris

#!/usr/bin/perl -Tw
use Perl::Always or die;
my $perl_version = (5.12.5);
print $perl_version;