If the file is not too large to read into memory you can slurp the whole thing and then split into "records" at points preceded by a line terminator and followed by a digit. You can then sort using a Scwhartzian Transform.

$ perl -Mstrict -Mwarnings -E '
open my $inFH, q{<}, \ <<EOD or die $!;
2 [...]
  [line1]
  [line2]
  [line3]
3 [...]
  [line1]
1 [...]
  [line1]
  [line2]
2 [...]
  [line1]
  [line2]
EOD

my $input = do {
   local $/;
   <$inFH>;
   };
close $inFH or die $!;

print for
   map  { $_->[ 0 ] }
   sort { $a->[ 1 ] <=> $b->[ 1 ] }
   map  { [ $_, m{\A(\d+)} ] }
   split m{(?<=\n)(?=\d)}, $input;'
1 [...]
  [line1]
  [line2]
2 [...]
  [line1]
  [line2]
  [line3]
2 [...]
  [line1]
  [line2]
3 [...]
  [line1]
$
[download]

I hope this is helpful.

I prefer a line-by-line approach and create a new array each time a line starting with a number is encountered. I assume that the data fits into memory, otherwise sorting will be difficult:

use strict;
use warnings;

my @lines;
while(<DATA>){
        push @lines, [$1] if /^(\d+)/;
        push @{$lines[-1]}, $_;
}
print @$_[1..@$_-1] for sort { $a->[0] <=> $b->[0] } @lines;

__DATA__
2 [...]
  [line1]
  [line2]
  [line3]
3 [...]
  [line1]
1 [...]
  [line1]
  [line2]
2 [...]
  [line1]
  [line2]
[download]

G'day monkprentice,

Here's another way to do it:

#!/usr/bin/env perl

use strict;
use warnings;

my @data;
map { /^\d+/ ? push(@data, $_) : ($data[-1] .= $_) } <DATA>;
print sort { ($a =~ /^(\d+)/)[0] <=> ($b =~ /^(\d+)/)[0] } @data;

__DATA__
2 [...]
  [line1]
  [line2]
  [line3]
3 [...]
  [line1]
1 [...]
  [line1]
  [line2]
2 [...]
  [line1]
  [line2]
[download]

Output:

1 [...]
  [line1]
  [line2]
2 [...]
  [line1]
  [line2]
  [line3]
2 [...]
  [line1]
  [line2]
3 [...]
  [line1]
[download]

As well as looking at elegance, you might want to consider comparing whatever solutions are suggested for efficiency (with Benchmark).