G'day ozboomer,

"I just can't seem to get my head to work with regex very well :("
...
"perlre... and "Perl Cookbook" don't really help me too much..."

Before delving into perlre, I'd recommend reading though perlrequick and perlretut.

I believe the following code does what you want. (See Notes at the end.)

#!/usr/bin/env perl -l

use strict;
use warnings;

my $master = 'comp.hw.';
my @items = qw{
    comp. comp.hw. comp.hw.new. comp.hw.hw. comp.sw.old. muse.hw.new. 
+ancient.
    comp comp.hw comp.hw.new comp.hw.hw comp.sw.old muse.hw.new ancien
+t
};

for my $level (1 .. split /\./, $master, -1) {
    print "Match Level: $level";

    my $re = '^'
           . join('\.' => (split /\./, $master, $level + 1)[0 .. $leve
+l - 1]);
    $re .= $re =~ /\.$/ ? '[^.]' : '(?:[.]|$)';
    print "Matching: /$re/";

    print "\t$_" for grep { /$re/ } @items;
}
[download]

Output:

Match Level: 1
Matching: /^comp(?:[.]|$)/
    comp.
    comp.hw.
    comp.hw.new.
    comp.hw.hw.
    comp.sw.old.
    comp
    comp.hw
    comp.hw.new
    comp.hw.hw
    comp.sw.old
Match Level: 2
Matching: /^comp\.hw(?:[.]|$)/
    comp.hw.
    comp.hw.new.
    comp.hw.hw.
    comp.hw
    comp.hw.new
    comp.hw.hw
Match Level: 3
Matching: /^comp\.hw\.[^.]/
    comp.hw.new.
    comp.hw.hw.
    comp.hw.new
    comp.hw.hw
[download]

Notes:

• Your OP had all @items with a terminal dot; your clarification later in the thread suggests this isn't the case: I've used both in my code to show it handles either case.
• Programmatically determining the levels, rather than using a hard-coded value, allows the script to be reused with any value for $master.
• Note that I've used the strict avd warnings pragmata. I strongly recommend you get into the habit of doing this also.
• Overall, your code has a C-like feel to it (e.g. instances of for (;;) and printf()); I've provided a more Perl-like way of doing it.