Hello joshywashy,

Without <code>...</code> tags around your data, we can only guess at how it’s formatted. If each each record occupies a separate line, like this:

0x0 in mmgsdi_evt_cb mmgsdi X mmgsdi Y
0xd in mmgsdi_evt_cb
0x1a in mmgsdi_evt_cb
...
[download]

then your approach should work fine (once the syntax error is fixed, of course). But if, as I suspect, the data is all on one line, then you need a more sophisticated strategy. Here is one approach:

#! perl
use strict;
use warnings;

my ($process) = <DATA>;     # slurp in all the data at once

# Use a look-ahead assertion
while ($process =~ /(0x[0-9a-f]{1,2})(.*?)(?=0x[0-9a-f]{1,2}|\Z)/gi)
{
    my ($hex, $text) = ($1, $2);
    print "Match found: $hex$text\n" if $text =~ /in mmgsdi_evt_cb/;
}

print "Finished\n";

__DATA__
0x0 in mmgsdi_evt_cb mmgsdi X mmgsdi Y 0xd in mmgsdi_evt_cb 0x1a in mm
+gsdi_evt_cb 0xe in mmgsdi_evt_cb 0xf in mmgsdi_evt_cb mmgsdi Z 0x13 i
+n mmgsdi_evt_cb mmgsdi Z mmgsdi Z
[download]

Output:

15:31 >perl 882_SoPW.pl
Match found: 0x0 in mmgsdi_evt_cb mmgsdi X mmgsdi Y
Match found: 0xd in mmgsdi_evt_cb
Match found: 0x1a in mmgsdi_evt_cb
Match found: 0xe in mmgsdi_evt_cb
Match found: 0xf in mmgsdi_evt_cb mmgsdi Z
Match found: 0x13 in mmgsdi_evt_cb mmgsdi Z mmgsdi Z
Finished

15:51 >
[download]

Hope that helps,

G'day joshywashy,

As already pointed out (either directly or via link), in order for us to help you, you need to provide:

• The input data in a form that shows us exactly what it looks like.
• The actual code you're running so we can also run it.
• The actual output your code is producing (including any error or warning messages).
• The expected output, i.e. what you really wanted.

In the code you posted, you have a definite problem with "while<$process>". I suspect you also have a problem with "elsif(/something else/)".

Is this closer to what you were trying to achieve:

#!/usr/bin/env perl

use strict;
use warnings;

while (<DATA>) {
    if (/in mmgsdi_evt_cb/) {
        print 'MATCH: ', $_;
    }
    else {
        print 'OTHER: ', $_;
    }
}

__DATA__
0x0 in mmgsdi_evt_cb
mmgsdi X
mmgsdi Y
0xd in mmgsdi_evt_cb
0x1a in mmgsdi_evt_cb
0xe in mmgsdi_evt_cb
0xf in mmgsdi_evt_cb
mmgsdi Z
0x13 in mmgsdi_evt_cb
mmgsdi Z
mmgsdi Z
[download]

Output:

MATCH: 0x0 in mmgsdi_evt_cb
OTHER: mmgsdi X
OTHER: mmgsdi Y
MATCH: 0xd in mmgsdi_evt_cb
MATCH: 0x1a in mmgsdi_evt_cb
MATCH: 0xe in mmgsdi_evt_cb
MATCH: 0xf in mmgsdi_evt_cb
OTHER: mmgsdi Z
MATCH: 0x13 in mmgsdi_evt_cb
OTHER: mmgsdi Z
OTHER: mmgsdi Z
[download]

... lots of words ... not compiling code ...

Please see How do I post a question effectively? and post code that both compiles and demonstrates the problem

*gah* a warning about the title would have been nice, did not mean to post that *embarrassed*

Bullshit is embarrassing?

(fascinating ... my Swype dictionary is too polite to know "shit" or "bullshit")

Cheers Rolf

( addicted to the Perl Programming Language)