Re^2: Question on "my" in the variables

Actually access to the pad (i.e. where lexical variables are stored) is about 40% faster than access to the stash (i.e. where package variables are stored).

The issue is not so much about declaring a million variables, but accessing a few variables a million times. For example, if you're finding the average of a few million small numbers, you may notice the difference between package variables and lexicals.

use strict;
use warnings;
use Attribute::Benchmark;

my @rands = map rand, 1..5_000_000;

sub mean_via_lexicals :Benchmark
{
    my @nums = @rands;
    
    my $count = @nums;
    my $total = 0;
    for (my $i=0; $i < @nums; $i++) {
        $total += $nums[$i];
    }
    
    $total / $count;
}

sub mean_via_globals :Benchmark
{
    our @nums = @rands;
    
    our $count = @nums;
    our $total = 0;
    for (our $i=0; $i < @nums; $i++) {
        $total += $nums[$i];
    }
    
    $total / $count;
}

__END__
                  s/iter  mean_via_globals mean_via_lexicals
mean_via_globals    7.37                --              -12%
mean_via_lexicals   6.45               14%                --
[download]

Though I agree that speed is not usually the main reason for preferring lexical variables over package variables. The avoidance of action at a distance is generally the most important.

use Moops; class Cow :rw { has name => (default => 'Ermintrude') }; say Cow->new->name

Comment on Re^2: Question on "my" in the variables Download Code