my %parent = ( 
    europe => [qw|
                london
                moscow
               |],
    asia   => [qw|
                tokyo
                seoul
               |],
    africa => [qw|
                cario
                algiers
               |],
     );
[download]

Second, do you care about determinism/repeatability in where a city rolls over to? You could just cycle over keys, and push the cities onto the next taker:

sub fallover {
    my ($hash, $failure) = @_;
    my $list = delete($hash->{$failure}) or return;
    my @targets = keys %$hash;
    my $i = 0;
    while (@$list) {
        my $city = shift @$list;
        push @{$hash->{$targets[$i++]}}, $city;
        $i %= @targets;
    }
}
[download]

Thanks for the feedback. I failed to mention the failover sites are predetermined. So in a scenario, if Europe goes down, london fails to asia, and moscow fails to africa. If asia goes down, london is then isoloated (no further failover available). Tokyo would fail to Africa, and Seoul (slated to failover to europe) would also be isolated.

The option of having the sites roll to the next available parent can't work.

G'day ahjohnson2,

The following achieves the results specifed in your OP and in your subsequent update.

Note the different data structure I've used. The order of continents is important so I've used an array of hashrefs each with a single continent key. The order of cities is also important so the values of those keys are arrayrefs.

[Also note that you've misspelled "Cairo" two different ways — this will cause errors that may be hard to track down — taking care over such details is important.]

#!/usr/bin/env perl -l

use strict;
use warnings;

use Data::Dump;

my @parent = (
    { Europe => [ qw{ London Moscow } ] },
    { Asia => [ qw{ Tokyo Seoul } ] },
    { Africa => [ qw{ Cairo Algiers } ] },
);

my @current;
reset_current(\@parent, \@current);

print '*** Starting State ***';
print_current_state(\@current);

print '*** Asia Down ***';
failover(Asia => \@current);
print_current_state(\@current);

print '*** Reset State ***';
reset_current(\@parent, \@current);
print_current_state(\@current);

print '*** Europe Down ***';
failover(Europe => \@current);
print_current_state(\@current);

print '*** Asia Down ***';
failover(Asia => \@current);
print_current_state(\@current);

sub failover {
    my ($down, $current) = @_;

    my @cities_to_failover
        = map { (keys %$_)[0] eq $down ? @{$_->{$down}} : () } @$curre
+nt;

    for (@$current) {
        my ($continent) = keys %$_;
        next unless @{$_->{$continent}};

        if ($continent eq $down) {
            @{$_->{$continent}} = ();
        }
        else {
            push @{$_->{$continent}}, shift @cities_to_failover;
        }
    }
}

sub print_current_state {
    my ($current) = @_;
    dd $current;
}

sub reset_current {
    my ($parent, $current) = @_;

    @$current = ();

    for (@$parent) {
        my ($continent) = keys %$_;
        push @$current, { $continent => [ @{$_->{$continent}} ] };
    }
}
[download]

Output:

*** Starting State ***
[
  { Europe => ["London", "Moscow"] },
  { Asia => ["Tokyo", "Seoul"] },
  { Africa => ["Cairo", "Algiers"] },
]

*** Asia Down ***
[
  { Europe => ["London", "Moscow", "Tokyo"] },
  { Asia => [] },
  { Africa => ["Cairo", "Algiers", "Seoul"] },
]

*** Reset State ***
[
  { Europe => ["London", "Moscow"] },
  { Asia => ["Tokyo", "Seoul"] },
  { Africa => ["Cairo", "Algiers"] },
]

*** Europe Down ***
[
  { Europe => [] },
  { Asia => ["Tokyo", "Seoul", "London"] },
  { Africa => ["Cairo", "Algiers", "Moscow"] },
]

*** Asia Down ***
[
  { Europe => [] },
  { Asia => [] },
  { Africa => ["Cairo", "Algiers", "Moscow", "Tokyo"] },
]
[download]