This line:

my @array = <FILE>;
[download]

...creates a lexically scoped variable named @array, which is actually a completely different variable from the package global promised to Exporter, named @array. The package global's full name is @xyz::array... and it doesn't exist in your program. Aside from telling Exporter that you intend to export it, you never declare it nor populate it with any value.

You would be able to export @array if it were declared with our instead of my; lexical variables cannot be exported, while package globals may be. Exporting variables is usually the wrong approach though, but it is possible.

If you follow the link and learn about Symbol tables, package scope (our) then some of these mechanisms may be useful.

However , the most robust and common method of extracting data from packages is to use accessors, which is essentially a sub inside a package that returns the value of the variable you seek.

If you need to MODIFY the value, you typically use a mutator - google these terms to get a better idea of how they are used.

Defining a module with accessor and mutator (get_* and set_*) functions has already been discussed. Another approach is to define iterators to access data. Happily, a file handle is already an iterator (or more accurately, is structured to be used by an iterator like readline). You can define functions in your module to interact with, in this case, a file handle and yet keep it absolutely private. A very simple example:

File use_Getfile_1.pl:

use warnings;
use strict;

use Getfile;

print qq{printing from file }, Getfile->FILENAME, qq{\n};

print Getfile->content;  # in list context

Getfile->reset;  # start again
print scalar Getfile->content;
print scalar Getfile->content;
[download]

File Getfile.pm:

# Getfile.pm

package Getfile;

use 5.008;
use warnings;
use strict;


use constant FILENAME => 'qwerty.txt';

open my $fh, '<', FILENAME or die qq{opening }, FILENAME, qq{: $!};

sub content { return <$fh>; }

sub reset { seek $fh, 0, 0 or die qq{seeking }, FILENAME, qq{: $!}; }

1;
[download]

File qwerty.txt:

line 1: The rain in Spain
line 2: falls mainly on the plain.
line 3: The quick brown fox jumps over
line 4: the lazy dog.
line 5: How now, brown cow?
[download]

Output:

c:\@Work\Perl\monks>perl use_Getfile_1.pl
printing from file qwerty.txt
line 1: The rain in Spain
line 2: falls mainly on the plain.
line 3: The quick brown fox jumps over
line 4: the lazy dog.
line 5: How now, brown cow?
line 1: The rain in Spain
line 2: falls mainly on the plain.
[download]

package Foo;

use strict;
use Exporter 'import';

# Export on demand, so the caller knows
# where these came from.
our @EXPORT_OK = qw(get_array populate_array);

{
    my @array; # can only be accessed in this block

    sub get_array { \@array }
    
    sub populate_array { @array = 'a' .. 'h' }
}

1;
[download]

% perl -de0

Loading DB routines from perl5db.pl version 1.37
Editor support available.

Enter h or 'h h' for help, or 'man perldebug' for more help.

main::(-e:1):   0
  DB<1> use Foo qw(get_array populate_array)

  DB<2> x get_array()
0  ARRAY(0x7fa9ac81a298)
     empty array
  DB<3> populate_array()

  DB<4> x get_array()
0  ARRAY(0x7fa9ac81a298)
   0  'a'
   1  'b'
   2  'c'
   3  'd'
   4  'e'
   5  'f'
   6  'g'
   7  'h'
  DB<5>
[download]

Variable Scoping in Perl: the basics