foreach my $var ( @{ $form->{PR} } ) {
    if ($var->{'id'} == $form->{'id'}) {
        print qq|elem->key $var->{id} eq $form->{"id"}\n|;
        print qq|\t\t cleared? $var->{cleared} $form->{"cleared"}\n|;
        if ( $var->{cleared} != $form->{"cleared"} ) {
            $var->{cleared} = $form->{"cleared"};
            print qq|\t\t FIXED $var->{cleared} $form->{"cleared"}\n|;
        }
    }
    else {
        print  qq|var id: $var->{id} ne form $form->{"id"}\n|;
    }
}
[download]

var id: 10368 ne form 12594
var id: 12585 ne form 12594
var id: 12592 ne form 12594
elem->key 12594 eq 12594
         cleared? 0 1
         FIXED 1 1
[download]

G'day aturtle,

In order to get a better idea of how to write your code, perhaps the first thing to do would be to take a look at the general layout of your complete data structure (which is a hashref assigned to $form).

{
    id      => integer,
    cleared => boolean,
    PR      => [
        { ... },
        ...
        { ... },
    ],
}
[download]

Now that the structure is clear, you should be able to see how misleading the first line of your outer loop is:

foreach my $key ( @{ $form->{PR} } ) {
[download]

Each of the elements in @{ $form->{PR} } are hashrefs, not keys.

You attempt to clarify this (by writing unnecessary code) with my %elem = %{$key}; however, you've possibly confused yourself even more because right below this you assign an actual key to another misleadingly named variable ($var) and then make the mistake of using it as a hashref (i.e. $var->{id}):

         foreach my $var ( keys %elem ) {  
          if ($var->{id} == $form->{"id"}){
[download]

A logical indentation of your code would make it easier to both read and maintain. I didn't find it easy to understand without close study (which shouldn't be necessary for fairly straightforward code such as this). This poor layout may well have been a contributing factor in some of the errors you've made. You can get some hints and tips on how to improve this from "perlstyle - Perl style guide"; you can use perltidy to reformat your code to your chosen style.

I'd also recommend you read UNIVERSAL. In the SYNOPSIS, you'll see "but never do this!" followed by examples similar to usages in your code. The ref function would have been a better choice here; also see the reftype function in the built-in Scalar::Util module.

Here's an example of how I might have searched through your data structure and made conditional changes to it:

#!/usr/bin/env perl -l

use strict;
use warnings;

use Data::Dumper;

my $form = {
    id      => 12594,
    cleared => 1,
    PR      => [
        { id => 10368, cleared => 0 },
        { id => 12594, cleared => 0 },
    ],
};

print '*** BEFORE ***';
print Dumper $form;

for my $hash_ref (@{$form->{PR}}) {
    if ($hash_ref->{id} == $form->{id}) {
        $hash_ref->{cleared} = $form->{cleared};
    } 
}

print '*** AFTER ***';
print Dumper $form;
[download]

Output:

*** BEFORE ***
$VAR1 = {
          'cleared' => 1,
          'id' => 12594,
          'PR' => [
                    {
                      'cleared' => 0,
                      'id' => 10368
                    },
                    {
                      'cleared' => 0,
                      'id' => 12594
                    }
                  ]
        };

*** AFTER ***
$VAR1 = {
          'cleared' => 1,
          'id' => 12594,
          'PR' => [
                    {
                      'cleared' => 0,
                      'id' => 10368
                    },
                    {
                      'cleared' => 1,
                      'id' => 12594
                    }
                  ]
        };
[download]

[Also consider using Data::Dump. In many instances, it's a better choice than Data::Dumper.]

When I run this code I would expect HASH ELEM: to print the contents of each anonymous hash in the array not just the first one.

Well, the error message you get is mighty informative :) even more so if you  use diagnostics;

The error

Can't use string ("source") as a HASH ref while "strict refs" in use a
+t duck
        line 77 (#1)
    (F) Only hard references are allowed by "strict refs".  Symbolic
    references are disallowed.  See perlref.

Uncaught exception from user code:
        Can't use string ("source") as a HASH ref while "strict refs" 
+in use at duck line 77.
[download]

The error is referring to this code

        foreach my $var ( keys %elem ) {
            if ( $var->{id} == $form->{"id"} ) {
[download]

Here is what I would do

#!/usr/bin/perl --
use strict; use warnings; use Data::Dump qw/ dd /;
my $form = {
  PR => [
    {
      cleared => 0,
    },
    [],
    { deraelc => 1 },
    {
      cleared => 0,
    },
    \'yo',
    { deraelc => 1 },
  ],
};

for my $ref ( @{ $form->{PR} } ){
    if( UNIVERSAL::isa( $ref,'HASH' ) ){
        dd( HASH => $ref );
    }elsif( UNIVERSAL::isa( $ref,'ARRAY' ) ){
        dd( ARRAY => $ref );
    }else{
        dd( ELSE => $ref );
    }
}
__END__
[download]

Except replace  dd( $ref ); with doHashThing( $ref ); and doArrayThing( $ref ); ... respectively

Then the first thing you do in doHashThing is dd()umper up the hash to see what you can see :) .... I'd even start a new file for each doThing until I'm comfortable with keys/hashes...