How about losing the duplicates while sorting? Here is the quicksort implementation from Rosetta Code:

sub quick_sort {
    my @a = @_;
    return @a if @a < 2;
    my $p = pop @a;
    quick_sort(grep $_ < $p, @a), $p, quick_sort(grep $_ >= $p, @a);
}
 
my @a = (4, 65, 2, -31, 0, 99, 83, 782, 1);
@a = quick_sort @a;
print "@a\n";
[download]

(This is for sorting numbers.) If you now replace >= with > so you get

quick_sort(grep $_ < $p, @a), $p, quick_sort(grep $_ > $p, @a);
[download]

you will get a sorted array without duplicates.

Perhaps this will be suitable (for your class exercise):

#!/usr/bin/env perl -l

use strict;
use warnings;

my @initial = qw{q w e r t y q w e r t y};
print "Initial: @initial";

my $last = '';
my @unique = map { $last eq $_ ? () : ($last = $_) } sort @initial;
print "Unique:  @unique";
[download]

Output:

Initial: q w e r t y q w e r t y
Unique:  e q r t w y
[download]

Update (alternative solution): You could even skip the creation of the unsorted array (your @array_q3):

#!/usr/bin/env perl -l

use strict;
use warnings;

my $last = '';
my @unique = map { $last eq $_ ? () : ($last = $_) } sort map { split 
+} <DATA>;
print "Unique:  @unique";

__DATA__
I am supposed to create a unique array
I am not supposed to use hashes
[download]

Output:

Unique:  I a am array create hashes not supposed to unique use
[download]

Many thanks to all of you guys!!

I wonder, could this be done using the splice function as well? But how would you use it?

foreach my $elem (@sorted) {
    push @uniq, $elem if !@uniq || $elem ne $uniq[-1];
}

# OR

my @uniq = shift @sorted;
$uniq[-1] ne $_ && push @uniq, $_ for @sorted;
[download]

$ perl -e 'my $prev; my @c = qw /a c d e r f e a e z e a /; print join
+ " ", grep { $_ ne $prev and $prev = $_;} sort @c'
a c d e f r z
[download]

my @array_q3=(); #create the array to store all words in the file
open INFILE3, "<file";
while( my $line3 = <INFILE3>)  
{   
    chomp $line3;
    push @array_q3, $line3;    
}
close INFILE3;

#sort the array so we can identify the duplicates
my @sorted_array_q3 = sort(@array_q3);
my @unique_array;

#iterate through the sorted array and check for unique elements
foreach my $element ( @sorted_array_q3 )
{
  if ( ! grep( /$element/, @unique_array ) )
  {
     push( @unique_array, $element );
  }
}

#print the unique elements in the file clean.acc\n";
open OUTFILE3, ">unique_codes";
for (my $m=0; $m<=$#unique_array; $m++)
{
  print OUTFILE3 $unique_array[$m]."\n";
}
close OUTFILE3;
[download]

Got it!


if ( ! grep ( /^$element$/, @unique_array ) )
[download]

Great that you found a solution yourself

Since you didn't follow your own idea of using sorting to identify doubles the sort step is now useless.

To follow your original plan you would have to do something like this:

my $previous="";
foreach my $element ( @sorted_array_q3 )
{
  if ( $element ne $previous )
  {
     push( @unique_array, $element );
  }
  $previous= $element;
}
[download]