Re: Very basic question on performance

Your examples do not produce the same results. The first one multiplies $x_sq * $y_sq, while the second example adds the equivalent terms. In my benchmark I changed the second code snippet to multiply instead.

The Benchmark module is sort of the standard module used in testing and comparing code snippets. The following script is an example of how to use it to check what your intuition is telling you:

use Inline C => 'DATA';
use Benchmark 'cmpthese';

sub vdiag {
  my( $x, $y ) = @_;
  my $x_sq = $x * $x;
  my $y_sq = $y * $y;
  my $prod = $x_sq * $y_sq;
  my $res  = sqrt($prod);
  return $res;
}

sub ediag {
  return sqrt( $_[0] * $_[0] * $_[1] * $_[1] );
}

cmpthese( -5, {
  cdiag  => 'cdiag(7,9)',
  vdiag  => 'vdiag(7,9)',
  ediag  => 'ediag(7,9)',
} );


__DATA__
__C__

#include <math.h>

double cdiag ( double x, double y ) {
  double x_sq = x * x;
  double y_sq = y * y;
  double prod = x_sq * y_sq;
  return sqrt(prod);
}
[download]

That produces the following comparison table:

$ ./mytest.pl
           Rate vdiag ediag cdiag
vdiag 1589859/s    --  -49%  -82%
ediag 3127854/s   97%    --  -64%
cdiag 8603134/s  441%  175%    --
[download]

So your intuition was correct, that declaring a bunch of variables takes a little longer. But you do have to put it in perspective; 1589859 iterations per second is already very fast. And if you are really concerned with performance in a tight loop or something, eliminating the clarity that comes from using named variables is, in this case, not the most effective solution. The C solution is still readable, and achieves 8603134 iterations per second. Write your Perl how you would like to read it back in six months. And when performance is a real bottleneck, take your biggest swing at the problem first.

Dave

Comment on Re: Very basic question on performance Select or Download Code

Replies are listed 'Best First'.
Re^2: Very basic question on performance by AnomalousMonk (Archbishop) on Mar 14, 2014 at 13:58 UTC
Write your Perl how you would like to read it back in six months. Write your Perl how you would like to read it back in six months at 3 AM, and your deadline to deliver your working, tested project is 8 AM.	[reply]
Re^3: Very basic question on performance by davido (Cardinal) on Mar 14, 2014 at 17:05 UTC
Or in my case, at 9:30am, with the 3yo and 5yo kids, under my "supervision", playing nearby. ;) Dave	[reply]
Re^4: Very basic question on performance by AnomalousMonk (Archbishop) on Mar 15, 2014 at 11:59 UTC
Ah, the joys of self employment! Or are you off-site/working-from-home, but otherwise normally employed? Not that it's any of my business...	[reply]
Re^2: Very basic question on performance by Laurent_R (Canon) on Mar 14, 2014 at 09:37 UTC
I often use named variable for better clarity, but in this case, I find ediag to be more readable than vdiag, because you see immediately the math formula. It is by looking at the ediag function that I quickly saw that it can be simplified to: `sub ediag { return $_[0] * $_[1]; }` [download] as I said in my other post. I would not pick up that immediately when looking at vdiag.	[reply] [d/l]
Re^3: Very basic question on performance by davido (Cardinal) on Mar 14, 2014 at 15:19 UTC
Or more accurately: `sub ediag { return abs($_[0]) * abs($_[1]); }` [download] ...or... `sub ediag { abs(shift) * abs(shift); }` [download] It's possible (maybe even probable) that since the OP showed one subroutine that did this: `sub one { sqrt( $_[0] * $_[0] * $_[1] * $_[1] ) }` [download] ...and another that did this: `sub another{ sqrt( $_[0] * $_[0] + $_[1] * $_[1] ) }` [download] ...that we (I) should have been looking at his second example all along, and should have considered the first one a typo. If that's the case, then the square root of the sum of two squares does make more sense. Dave	[reply] [d/l] [select]
Re^4: Very basic question on performance by morrin (Acolyte) on Mar 14, 2014 at 15:28 UTC
Thanks Dave, you were correct. I had a typo. It was suppose to be the square root of the sum of the squares for both. :-)	[reply]
Re^4: Very basic question on performance by Laurent_R (Canon) on Mar 14, 2014 at 18:42 UTC
Yes, Dave, you are correct, it should rather be something like: `return abs ( $_[0] * $_[1]);` [download] But my point was really to say that, although I am very often using named variables for better clarity (and also to avoid changing inadvertently the parameter in the calling function), I found that, in this case, the ediag function is in my humble opinion actually clearer than the vdiag function, because you can see immediately the math expression being returned to the caller.	[reply] [d/l]
Re^5: Very basic question on performance by davido (Cardinal) on Mar 14, 2014 at 18:57 UTC
Re^6: Very basic question on performance by Laurent_R (Canon) on Mar 14, 2014 at 20:01 UTC
Re^2: Very basic question on performance by Old_Gray_Bear (Bishop) on Mar 15, 2014 at 23:30 UTC
Write your Perl like it's 0300, the ENTIRE FINANCIAL SYSTEM is down, and the Union Payroll has to be delivered by 0800. Oh, and you have three levels of Management on a conference call asking you "How's it going?" every five minutes. AND the coffee pot just burned out the heating element. ---- I Go Back to Sleep, Now. OGB	[reply]