You don't need to use regexes for this. In pseudocode:

use List::MoreUtils qw{uniq}
while (<FH>){
chomp;
convert each line to an array of numbers splitting by "-"
sort the resulting list of numbers
and apply uniq to this list:  my @list_of_unique_items = uniq @list;
join or print again each element followed by a "-"
chomp again if needed to delete the last "-"
undef the array
process the next line
[download]

..appreciate it guys but I'm trying to make this solution simpler & shorter- not longer!

This isn't too bad I spose.. Seems to work in a 1-liner:
s/(\d\d)((-\d\d)*?)(-\1)/$1$2/g while /(\d\d).*(-\1)/;

Which can probably be further reduced to:

$ cat 1078350.in
12-12
12-12-12
12-13-12-13
12-12-13-13
12-13-13-14
$ perl -pe '1 while s/(\d\d)(.*?)(?:-\1)/$1$2/g' 1078350.in
12
12
12-13
12-13
12-13-14
[download]

Also using a hash but in a different way:

use strict;
use warnings;

my @strings = qw( 12-12 12-12-12 12-13-12-13 12-12-13-13 12-13-13-14 )
+;
 
for (@strings) {
  my %hash;
  s/(\-?)(\d\d)/ $hash{$2}++ ? '' : $1.$2 /ge;
  print "$_\n";
}
[download]

Another way.

$ perl -Mstrict -Mwarnings -E '
say join q{-}, do {
   my %seen;
   grep { not $seen{ $_ } ++ } split m{-};
   } for qw{
      12-12
      12-12-12
      12-13-12-13
      12-12-13-13
      12-13-13-14
      };'
12
12
12-13
12-13
12-13-14
$
[download]

I hope this is helpful.

use strict;
use warnings;

my @strings = qw( 12-12 12-12-12 12-13-12-13 12-12-13-13 12-13-13-14 )
+;
 
for (@strings) {
    my $prev = -1; # numbers being separated by dashes, I assume that 
+a negative value is not possible
    print join "-", grep {$prev != $_ and $prev = $_} sort {$a <=> $b}
+ split /-/, $_;
    print "\n";
}
[download]

12
12
12-13
12-13
12-13-14
[download]

while(<DATA>){
%h = ();
undef $h{$1} while(s/(\d\d)//);
print join ("-", sort keys %h),"\n";
}

__DATA__
12-12
12-12-12
12-13-12-13
12-12-13-13
12-13-13-14
[download]

I would also use matching instead of substitution. You mentioned in a private message that the substitution is faster (using such a trick would be worth a comment), but my benchmark doesn't show the effect. To speed things up, rather use my %h instead of %h = ().
Read more... (959 Bytes)
Output:

         Rate lenno choro
lenno 25358/s    --   -4%
choro 26458/s    4%    --
[download]

Perl 5.16.2, x86_64-linux-thread-multi.

Update: Significantly faster: use a hash slice undef @h{m/\d\d/g}; instead of the inner loop.

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

Yes, thank you for your reply, I apparently got mistaken,
I'm deeply sorry. You were right.
My results:

use Benchmark(cmpthese);
cmpthese(1000000, {
    'a' => sub {
        $_ = '12-12-12-12-12';
        undef $h{$1} while (s/(\d\d)//);
    },
    'b' => sub {
        $_ = '12-12-12-12-12';
        undef $h{$1} while (m/(\d\d)/g);
    },
    'c' => sub {
        $_ = '12-12-12-12-12';
        undef @h{m/\d\d/g};
    }
});
[download]

results:

      Rate    a    b    c
a 195427/s   -- -19% -35%
b 241896/s  24%   -- -20%
c 300933/s  54%  24%   --
[download]