G'day anakin30,

There seems to be a disconnect between your description, sample data and attempted code. Even your subsequent post (Re^2: search date occurance from csv column) does not make it clear what you want: if you're searching for '20140319', and that does not occur anywhere in the sample data you provide, surely you want "... 0 occurrences" (for both lines of output), not "... xx occurence" (as you've written for both).

All of this leaves me unclear as to what you're having difficulties with. Here's some possible areas where you might need help:

• Your code doesn't determine any search date (current date or otherwise).
• You have no code that compares a search date with any date extracted from your input file.
• You don't show any code that extracts the data in the 'date1' column.
• You're counting every line in the input file but you say you want to count matches in the 'date1' and 'date2' columns.
• Your print statement does not, in any way, resemble the "expected output" shown in your subsequent post (in this thread).

Here's a short script to show techniques for extracting your data, keeping a count and displaying the results based on search criteria. This isn't intended to be a solution (as your requirements are unclear) but should provide some pointers for achieving your goal.

#!/usr/bin/env perl -l

use strict;
use warnings;

my @counts;

while (<DATA>) {
    my @dates = map { substr $_, 0, 8 } (split /;/)[1, 2];
    ++$counts[$_]{$dates[$_]} for (0, 1);
}

for (qw{20110327 20140211 20140220}) {
    print "Search date: $_";
    print 'date1: ', $counts[0]{$_} || 0;
    print 'date2: ', $counts[1]{$_} || 0;
}

__DATA__
13645722;20110327203202.0Z;20140211204731.0Z
14947374;20110327203202.0Z;20140220135320.0Z
15962660;20110327203156.0Z;20131106113716.0Z
17480884;20110327212821.0Z;20131211143804.0Z
13054554;20110327203141.0Z;20131205162959.0Z
[download]

Output:

Search date: 20110327
date1: 5
date2: 0
Search date: 20140211
date1: 0
date2: 1
Search date: 20140220
date1: 0
date2: 1
[download]