G'day bshah,

"Open user.txt and iterate through each user and check each line on ldap.txt in dn: line."

That would mean you'd be reading your multi-gigabyte ldap.txt multiple times (i.e. once for every user in user.txt). Instead, read user.txt once and create a regex with a capture group containing an alternation of all the users. If that's unfamiliar to you, see "Perl regular expressions tutorial".

"If matches, then store the value of all the lines matching maillocaladdress to the varialbe , I assume in hash key/value pari but here the values are more than one."

What you want here is a "hash of arrays".

Putting all that together (based on your sample data):

#!/usr/bin/env perl

use strict;
use warnings;
use autodie;

my ($user_file, $ldap_file) = qw{pm_1079590_user.txt pm_1079590_ldap.t
+xt};

open my $user_fh, '<', $user_file;
my @users;
while (<$user_fh>) {
    chomp;
    push @users, $_;
}
close $user_fh;

my $user_re = 'uid=(' . join('|', @users) . '),';

my %user_ldap_data;

open my $ldap_fh, '<', $ldap_file;
my $user = '';
while (<$ldap_fh>) {
    if (/^dn:/) {
        $user = /$user_re/ ? $1 : '';
        next;
    }

    next unless $user;

    push @{$user_ldap_data{$user}}, $1 if /^maillocaladdress:\s+(\S+)/
+;
} 
close $ldap_fh;

use Data::Dump;
dd \%user_ldap_data;
[download]

Output:

{
  game  => [
             "game\@example.com",
             "game.test\@example.com",
             "game-test\@example.com",
           ],
  test1 => [
             "test1\@example.com",
             "test.team\@example.com",
             "test11\@example.com",
           ],
}
[download]

Thank you Ken

Do you mind explaining the following piece of code please ?


'uid=(' . join('|', @users) . '),';

$user = /$user_re/ ? $1 : ''
[download]


Kind Regards

"Do you mind explaining the following piece of code please ?"

Well, you've listed two pieces of code which appear in different parts of the script I posted:

"'uid=(' . join('|', @users) . '),';"

I've already provided a link to what's going on here: "... create a regex with a capture group containing an alternation of all the users. If that's unfamiliar to you, see "Perl regular expressions tutorial".". Was there something in that documentation that you didn't understand?

See "Perl functions A-Z" for information about join (or any of the other core functions I've used).

You could always run the code I provided with a print statement to see how that expression is evaluated.

"$user = /$user_re/ ? $1 : ''"

That's the ternary (aka conditional) operator: see "perlop: Conditional Operator".

-- Ken

That looks like an extract from an ldap database. Have you considered instead using Net::LDAP to query the directory directly rather than parsing a dump 'by hand'?

LDAP queries support searching on loose text matches. (E.g. search key on 'maillocaladdress=test1*')

Failing that though, this looks like a fairly straightforward 'while' loop on a filehandle. If you're really insistent on hand-parsing an LDAP directory, you'll probably find the 'range' operator useful to read up on.

Hi,

Thanks for your reply. Yes, this is a database but its a backup file since this data is removed from current database so we need to use file instead of Net::LDAP

Please use <code> tags to enclose your data to improve its readability.