http://learn.perl.org/faq/perlfaq4.html#How-do-I-sort-an-array-by-anything-, http://perldoc.perl.org/perlfaq4.html#How-do-I-sort-an-array-by-%28anything%29%3f

Understanding the Schwartzian transform., Re: Sorting a HoH by values of the nested hashes,

G'day shekarkcb,

I got rid of the irrelevent data from the hash. I added more test data to better test the sorting process.

I've assumed that (1) "'NULL'" means a zero-length string; (2) the wanted sort order is undefs first, then zero-length strings, then numerical data in ascending order; (3) the output is an array of arrays for writing to a spreadsheet.

#!/usr/bin/env perl

use strict;
use warnings;

my %data = (
    A => [ 0, 1, 2, 3, 99,      5, 6 ],
    B => [ 0, 1, 2, 3, 9.9999,  5, 6 ],
    C => [ 0, 1, 2, 3, "",      5, 6 ],
    D => [ 0, 1, 2, 3, undef,   5, 6 ],
    E => [ 0, 1, 2, 3, 11,      5, 6 ],
    F => [ 0, 1, 2, 3, 123.0,   5, 6 ],
    G => [ 0, 1, 2, 3, '',      5, 6 ],
    H => [ 0, 1, 2, 3, undef,   5, 6 ],
    I => [ 0, 1, 2, 3, -11,     5, 6 ],
    J => [ 0, 1, 2, 3, -1.1,    5, 6 ],
);

my @rows = map {
    [ $_->[0] => @{$data{$_->[0]}} ]
}
sort {
    (! defined $a->[1]) ? -1 :
    (! defined $b->[1]) ?  1 :
    (! length $a->[1])  ? -1 :
    (! length $b->[1])  ?  1 :
    ($a->[1] <=> $b->[1])
}
map {
    [ $_ => $data{$_}[4] ]
} keys %data;

use Data::Dump;
dd \@rows;
[download]

Output:

[
  ["H", 0 .. 3, undef, 5, 6],
  ["D", 0 .. 3, undef, 5, 6],
  ["C", 0 .. 3, "", 5, 6],
  ["G", 0 .. 3, "", 5, 6],
  ["I", 0 .. 3, -11, 5, 6],
  ["J", 0 .. 3, -1.1, 5, 6],
  ["B", 0 .. 3, 9.9999, 5, 6],
  ["E", 0 .. 3, 11, 5, 6],
  ["A", 0 .. 3, 99, 5, 6],
  ["F", 0 .. 3, 123, 5, 6],
]
[download]

Very nice solution. I was also thinking of a succession of ternary operators to handle the undef or "null" special cases, but did not want in my earlier post to decide on those cases without the OP specifying the required behavior for those cases (which is why I suggested an example sorting on another field). Having said that, if the idea is just to sort the (final) sub-arrays (as I understood the OP's requirement), then the two calls to the map function seem unnecessary. We could have just this (using your test data):

use strict;
use warnings;

my %data = (
    A => [ 0, 1, 2, 3, 99,      5, 6 ],
    B => [ 0, 1, 2, 3, 9.9999,  5, 6 ],
    C => [ 0, 1, 2, 3, "",      5, 6 ],
    D => [ 0, 1, 2, 3, undef,   5, 6 ],
    E => [ 0, 1, 2, 3, 11,      5, 6 ],
    F => [ 0, 1, 2, 3, 123.0,   5, 6 ],
    G => [ 0, 1, 2, 3, '',      5, 6 ],
    H => [ 0, 1, 2, 3, undef,   5, 6 ],
    I => [ 0, 1, 2, 3, -11,     5, 6 ],
    J => [ 0, 1, 2, 3, -1.1,    5, 6 ],
);

my @rows = sort {
    (! defined $a->[4]) ? -1 :
    (! defined $b->[4]) ?  1 :
    (! length $a->[4])  ? -1 :
    (! length $b->[4])  ?  1 :
    ($a->[4] <=> $b->[4])
} values %data;
[download]

But here again, we don't really know what the OP exactly wants to get.

What you have there is exactly (or extremely close to) what I originally coded; however, after considering the OP's "writing these values to excel", I quickly changed that to a Schwartzian Transform.

You're quite correct about not knowing what the OP really wanted. With any of the suggested solutions, questions regarding how an undef is written to a spreadsheet remain outstanding (and this would almost certainly require further coding).

-- Ken

Thank you all for the reply. This is how i achieved the result.


1). Created another hash with 5th entry as value.
2). Sorted the that hash, moved keys to an array


my @sorted = sort { $subHash{$b} <=> $subHash{$a} } keys %subHash;
[download]

, @sorted had the required output.
Thanks agin for the pointers, closing the thread

Thanks

use strict;
use warnings;
use Data::Dumper

my %hash = (
       '10857' => [
                       '10857',
                       'Test-host1',
                       '192.168.162.124',
                       undef,
                       undef,
                       undef,
                       undef,
                       'Timeout while connecting to "192.168.162.124:1
+61"'
                     ],
          '10715' => [
                       '10715',
                       'Test-Host2',
                       '192.168.162.146',
                       'checkPing[{HOST.IP}]',
                       '108',
                       '108',
                       '2014-04-01 20:24:01',
                       ''
                     ],
          '10778' => [
                       '10778',
                       'Test-Host3',
                       '192.168.162.144',
                       'checkPing[{HOST.IP}]',
                       '392',
                       '359',
                       '2014-04-01 20:21:12',
                       ''
                     ],
        '10582' => [
                       '10582',
                       'Test-Host3',
                       '192.168.162.95',
                       'icmppingsec',
                       '117.390000',
                       '116.493000',
                       '2014-04-01 20:23:03',
                       ''
                     ]
);

my @sorted_array = sort {$a->[0] <=> $b->[0] } values %hash;

print Dumper \@sorted_array;
[download]

{$a->[0] <=> $b->[0] }
[download]

The result:

Something to do for undefs: coerce to zero.

Read more... (2 kB)

Yes, this is one way to do it. I just did not want to decide for the OP what to do for undef, empty strings and other such special cases where it is difficult to figure out how to sort them without knowing the functional context. I'll gladly update my proposal when (and if) the OP gives additional information.