Starting a whole thread just print a value is silly, but no more so than forking a process I suppose.

Notionally a direct equivalent:

#! perl -slw
use strict;
use threads;
use threads::shared;

my $sem :shared;
our $MAX //= 10;

my $array = 'list.txt';
open my $handle, '<', $array;
chomp(my @array = <$handle>);
close $handle;

my @threads;
for my $printme ( @array ) {
    push @threads, async{
        lock $sem;
        print $printme;
    };
    sleep 1 while threads->list( threads::running ) > $MAX;
}
$_->join for @threads;
[download]

A simplistic thread pool solution:

#! perl -slw
use strict;
use threads;
use threads::shared;
use Thread::Queue;

our $MAX //= 10;

my $sem: shared;
my $Q = new Thread::Queue;

sub thread {
    while( my $printme = $Q->dequeue ) {
        lock $sem;
        print $printme;
    }
}

my @threads = map async( \&thread ), 1 .. $MAX;

my $array = 'list.txt';
open my $handle, '<', $array;
chomp, $Q->enqueue( $_ ) while defined( $_ = <$handle> );
close $handle;

$Q->enqueue( (undef) x $MAX );
$_->join for @threads;
[download]

(Neither tested).

This would seem to be an equivalent:

#!/usr/bin/env perl

use strict;
use warnings;
use threads;
[download]

while (<DATA>) {
    threads->create(sub { print 'Thread ', threads->tid, ': ', $_ })->
+join;
}
[download]

Update: Apparently not equivalent - see BrowserUk's comments below.

__DATA__
list.txt line 1
list.txt line 2
list.txt line 3
[download]

Output:

Thread 1: list.txt line 1
Thread 2: list.txt line 2
Thread 3: list.txt line 3
[download]

The "Perl Threads Tutorial" would probably be a good place to start if you want to learn more.

This would seem to be an equivalent:

Not so. It is fatally flawed.

Your code is directly equivalent to:

#!/usr/bin/env perl

use strict;
use warnings;
use threads;

my $n = 0;
while (<DATA>) {
    print 'Thread ', ++$n, ': ', $_;
}
[download]

Ie. It exhibits no parallelism whatsoever.

---

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

Thanks for picking that up. I've updated my post.

-- Ken