In your code, you create the callback timer and immediately discard it, which prevents the timer from ever getting called:

sub {
...
            my $w = AnyEvent->timer(
                after => 0,
                interval => 5,
                cb => sub {
                    $session->write('5 seconds have passed');
                    $w_cond->send();
                }
            };
}
[download]

You need to keep $w alive until the timer has fired. The easiest way is the following pattern:

...
            my $w; $w = AnyEvent->timer(
                after => 0,
                interval => 5,
                cb => sub {
                    undef $w; # cleanup!
                    $session->write('5 seconds have passed');
                    $w_cond->send();
                }
            };
...
[download]

That way, the timer stays alive until it has fired.

Thanks for that advice also! I've modified the code in the OP, however, the behavior has stayed the same.

Please don't modify your original code that much, as people then can't learn from seeing your code progress through the stages.

The next step would be to add (much) more amounts of server-side logging. print or warn at every step of the process. At least add logging statements to the following points:

    mount '/echo' => SockJS->new(
        handler => sub {
            warn "Creating new session";
            my ($session) = @_;

            $session->on(
                'data' => sub {
                    my $session = shift;
                    warn "got new data";

                    $session->write('got your message');
                    warn "Wrote response";
                }
            );

            $session->write('connected');
            warn "Wrote greeting";

            my $w_cond = AnyEvent->condvar;
            my $w; $w = AnyEvent->timer(
                after => 0,
                interval => 5,
                cb => sub {
                    undef $w; # cleanup
                    $session->write('5 seconds have passed');
                    warn "Wrote timer message";
                    $w_cond->send();
                }
            );
            $w_cond->recv;
            warn "Leaving";
        };
    );
[download]

I believe you meant to say:

my $w;
sub {
...
    $w = AnyEvent->timer(
    ...
}
[download]

ie: you want $w outside of builder

On another glance

my $w; $w = AnyEvent->timer(
[download]

is correct, but

$w_cond->send();
[download]

within your timer cb is not what you want. From AnyEvent:

$w->recv; # enters "main loop" till $condvar gets ->send
[download]

You want to ->recv when you are done with things. Adding another timeout timer for example would do the trick allowing your timer to run couple of times and eventually terminating your timer and the main loop after 30 seconds:

my $w; $w = AnyEvent->timer(
    after => 0,
    interval => 5,
    cb => sub {
        $session->write('5 seconds have passed');
    }
);

my $timeout_timer; $timeout_timer = AnyEvent->timer(
    after => 0,
    interval => 30,
    cb => sub {
        undef $w;
        undef $timeout_timer;
        $session->write('Timeout after 30 seconds');
        $w_cond->send();
    }
);
[download]

G'day xtpu2,

[Disclaimer: I haven't used AnyEvent previously. The following information was gleaned from its (and AnyEvent::Intro's) documentation.]

"It is obvious that $w->recv is the culprit because if I comment out that line, the server works and outputs 'got your message' when I send a message to it. However, in that case the timer doesn't work."

This may only be part of the story, but it might help resolve the AnyEvent issue.

You're calling recv() on a time watcher when it should be called on a condition variable. Also, you'll need a send() method in your timer callback.

Here's a minimal example intended to roughly mirror the AnyEvent part of the code you posted:

#!/usr/bin/env perl -l

use strict;
use warnings;

use AnyEvent;
use AnyEvent::Strict;

print 'Start at: ', scalar localtime;

my $w_cond = AnyEvent->condvar;

my $w = AnyEvent->timer(
    after => 5,
    cb => sub {
        print 'Callback: ', scalar localtime;
        $w_cond->send;
    }   
);  

$w_cond->recv;
[download]

Output:

Start at: Wed Apr  9 12:06:50 2014
Callback: Wed Apr  9 12:06:55 2014
[download]

Thanks for those tips! I have modified the code accordingly and modified the OP. Unfortunately, the behavior of my code is the same (while your code snippet works correctly).

I guess, the module you create is already called from some event-driven system. In other words, your module is a "callback". The "callback" can't run it's own event distribution. You can register one more "callback" with the main system and then simply return control to the caller. The main system is then responsible for activating your new callback at appropriate time.

The AnyEvent module is event-distribution system. When you call $w->recv you activate this system, which blocks the main one, which in turn might trigger some time-out for killing your callback. Figure out how to add timers to the main framework. I don't know Plack and don't have any desire to study it, so I can't help you with this, sorry.

At the core, event-driven programming is very simple. The main part is manager looping over all possible events. When event is encountered, the manager checks if there are any "callbacks" waiting for this event. Those callbacks are activated and the looping continues. The callbacks must finish their work quickly and if necessary, they can register more callbacks for different events.

Everything else, is specific ways, how different managers keep track of callbacks and events.