When Moose sees this:

has 'successor' => (
    is => 'rw',
    isa => 'ChainOfResposibilityIf',
);
[download]

If the ChainOfResposibilityIf role has not yet been loaded (use/require), Moose needs to make a snap decision about what kind of thing ChainOfResposibilityIf is. It needs to set up everything for the attribute straight away - it doesn't wait until you actully make use of the attribute.

Anyway, Moose guesses that it's a class. So later, when you assign to the attribute, it checks $value->isa('ChainOfResposibilityIf') (which fails) instead of $value->DOES('ChainOfResposibilityIf') (which would pass).

Three possible solutions. Any of them will do:

• Load ChainOfResposibilityIf earlier. Before using it in an attribute definition. (This seems the most fragile solution to me, and is my least preferred, but it should work.)

• Instead of isa use does:

  has 'successor' => (
      is => 'rw',
      does => 'ChainOfResposibilityIf', # !!!
  );
  [download]

• Create an explicit type constraint object, and pass that to isa instead of passing the string "ChainOfResposibilityIf":

  use Moose::Util::TypeConstraints qw(role_type);
  has 'successor' => (
      is => 'rw',
      isa => role_type('ChainOfResposibilityIf'),
  );
  [download]

G'day jjyoung,

Welcome to the monastery.

The short answer may simply be what the error message is telling you. An instance of GenericCommandHandler IS-A GenericCommandHandler and IS-A CoRHandler (both of which are classes), but it IS-NOT-A ChainOfResponsibilityIf which is a role.

If that doesn't answer your question, then a longer answer may require some further input from you.

I created a './PM/1081903/ directory and populated it with:

$ cat ChainOfResponsibilityIf.pm
package PM::1081903::ChainOfResponsibilityIf;

use Moose::Role;

requires 'handleRequest';
requires 'addHandler';

1;
[download]

$ cat CoRHandler.pm
package PM::1081903::CoRHandler;

use Moose;
use Carp qw(confess croak);

with 'PM::1081903::ChainOfResponsibilityIf';

sub handleRequest { 1 }
sub addHandler { 1 }

sub _processCommand { 1 }

1;
[download]

$ cat GenericCommandHandler.pm
package PM::1081903::GenericCommandHandler;

use Moose;

extends 'PM::1081903::CoRHandler';

override  '_processCommand' => sub { };

1;
[download]

$ cat GCHSuccessor.pm
package PM::1081903::GCHSuccessor;

use Moose;

has 'successor' => (
    is => 'rw',
    isa => 'PM::1081903::ChainOfResposibilityIf',
);

1;
[download]

I then ran this script:

#!/usr/bin/env perl

use strict;
use warnings;

use PM::1081903::GenericCommandHandler;
use PM::1081903::GCHSuccessor;

my $gchs = PM::1081903::GCHSuccessor::->new(
    successor => PM::1081903::GenericCommandHandler::->new()
);
[download]

I got a lot of error output which started the same as you reported "Attribute (successor) does not pass the type constraint ...". See the spoiler for the full message.

I then changed this line in GCHSuccessor.pm

isa => 'PM::1081903::ChainOfResposibilityIf',
[download]

to

isa => 'PM::1081903::CoRHandler',
[download]

I reran the same script and no output at all was generated. Perhaps this is the (type of) change you need.

I then added this line to the end of that script:

print $gchs->successor->handleRequest(), "\n";
[download]

This produced 1 as its only output. So, the value of the successor attribute of the PM::1081903::GCHSuccessor object DOES the PM::1081903::ChainOfResposibilityIf role. Is that what you were trying to test?

If some, or all, of that hasn't answered your question, or my guesses at your class stucture were wrong, please provide actual code that we can run, along with a clear description of what trying to test or learn, such that we can point you in the right direction.