The central error that leads to the behaviour of your code are the following two lines:

...
foreach(@arr) {
    
    @IDINFO = split(/:/,"$arr[$_]");
...
[download]

You should see lots of warnings by Perl, because $arr[$_] will always be $arr[0], because $_ is not what you might think it is.

As a first approach to finding such errors yourself, I would suggest printing $_ and $arr[ $_ ] to make sure that what you see is what you think there should be.

As a first fix, use $_ instead of $arr[ $_ ].

In general, there are many things that you can improve in your program to make it more resilient and not rely on features that were superseded by features introduced in Perl 5:

$HAN = "handle";
$FILE = "passwd.txt";
open("$HAN", "$FILE")||die "Error opening file: $!\n";
[download]

Please do not use global filehandles. Whatever textbook promotes such use, it is hopefully very old, as this is a technique used in Perl 4. Using this technique relies on the idea that nobody nowhere in your program will ever use a filehandle with a similar name. The Perl5 way is to simply use lexical filehandles:

open my $HAN, $FILE
    or die "Error opening file '$FILE': $!";
[download]

Now, your file iteration logic is also problematic because it mixes two approaches:

while(<$HAN>) {
@arr = <$HAN>;
}
[download]

The while(<$HAN>) { reads one line from $HAN and stores it in $_.

The @arr= <$HAN> reads all remaining lines from $HAN and stores them in @arr.

You should use either one of the two idioms but not mix them.

...
    print "UID is: @IDINFO[2] \n";
    print "GID is: @IDINFO[3] \n";
...
[download]

The common way to write these is to use $ instead of @:

    print "UID is: $IDINFO[2] \n";
    print "GID is: $IDINFO[3] \n";
[download]

Thanks Corion for handpicking my problems. i learnt a lot.

G'day intoperl,

Welcome to the monastery.

There's builtin functions to do this. No need to reinvent this particular wheel. Try this from your command line:

$ perldoc -f getpwent
[download]

Thanks Ken, for bringing up getpwent. BTW, i used the other approach which did not mention getpwent, but still the job was done, by the code below :

my $HAN = "handle";
my $FILE = "passwd.txt";
open("$HAN", "$FILE")||die "Error opening file: $!\n";

while(<$HAN>) {
my ($name,$passwd,$uid,$gid,$gcos,$dir,$shell) = split(/:/,$_);
print "UID is: $uid\n";
print "GID is: $gid\n";

}

close("$HAN");
[download]

"Thanks Ken, for bringing up getpwent. BTW, i used the other approach which did not mention getpwent, but still the job was done, ..."

You're welcome. I'm glad you found a working solution.

For future reference, all of that code could have been replaced by:

while (my @pw = getpwent) {
    printf "UID is: %s\nGID is: %s\n", @pw[2,3]
}
[download]

By the way, take a look at open for better ways of doing: open("$HAN", "$FILE")

-- Ken

Thank you sir, i made a note of it. :)