The winner seems to be File::Map. It is less complicated to use, and at least performs in correct accordance to its documentation (unlike Sys::Mmap). ++ to leont once again.

use strict;
use warnings;

use File::Map 'map_file';

map_file my $map, '/usr/share/dict/words', '<';
while( $map =~ m/^(wal.*)$/mg ) {
  print "$1\n";
}
[download]

Though its user interface is fairly simple, it is a module where reading 100% of the documentation is probably a very good idea.

In principle this seems to work. Here's an example:

use strict;
use warnings;
use Sys::Mmap;

my $string;

open my $fh, '<', '/usr/share/dict/words' or die $!;

Sys::Mmap::mmap( $string, 0, MAP_SHARED, PROT_READ, $fh );

while( $string =~ m/^(wal.*)$/mg ) {
  print $1, "\n";
}

Sys::Mmap::munmap( $string ) or die "munmap: $!";
close $fh;
[download]

On my system I get a dump of everything in the dict/words file starting with 'wal'. However, I end up getting the following error message when munmap is called:

variable is not a string at ./mytest.pl line 17.
[download]

The XS code testing whether the variable being unmapped is a string is this:

if(SvTYPE(var) != SVt_PV) {
            croak("variable is not a string");
            return;
        }
[download]

...which doesn't strike me as wrong. Must be something in the XS for 'mmap' that is not happening properly.