you have 3 nested loops, this must be wrong.

Just read table.txt ONCE (open,loop,close) into a big hash with the numbers (second-column) as keys.

Then while reading values.txt check this hash (open,loop and test, close)

2 unnested loops, that's all you need.

HTH :)

update

corrected typo, thx Athanasius! :)

Here is somewhat simpler and more traditional code (with no module dependencies):

use strict;
use warnings;

open(my $table, "<", "table.txt") or die "Cannot open Tables";

my %ids2proteins;
while (<$table>){
  chomp;
  my ( $protein, $nbr) = split ;
  next unless $nbr;
  $ids2proteins{$nbr} = $protein;
}
close $table;

open(my $val, "<", "values.txt") or die "Cannot open Values";
while (<$val>){
  chomp;
  next unless length $_ > 1;
  next unless my $prot = $ids2proteins{$_};
  print "$prot => $_ \n";
}
close $val;
[download]

"Since you claim to be a "perl beginner" - kcott's (++) code may be a little esoteric."

To NetWallah: Thanks for the ++; esotericism was not the intention.

To To_Bz: If there was something in my original code you didn't understand, please feel free to ask; however, first see the clarification below.

"Here is somewhat simpler and more traditional code (with no module dependencies):"

The module (Inline::Files) was not intended for To_Bz's code; it was purely for my test.

I was aiming to use (what appeared to be) the smaller file (values.txt) to create the hash; then selectively printing from (what appeared to be) the larger file (table.txt).

As a clarification, here's the entire script I envisaged for To_Bz (correcting the open syntax errors and applying my lexical filehandle recommendation):

#!/usr/bin/env perl -l

use strict;
use warnings;
use autodie;

open my $table, '<', 'table.txt';
open my $values, '<', 'values.txt';

my %vals = map { $_ => 1 } <$values>;
print $_->[0] for grep { $vals{$_->[1]} } map { [ split / / ] } <$tabl
+e>;
[download]

[Note: autodie used in lieu of hand-crafting die messages for both open statements.]

-- Ken

G'day To_Bz,

Welcome to the monastery.

You can achieve that much more simply like this:

my %vals = map { $_ => 1 } <FILE2>;
print $_->[0] for grep { $vals{$_->[1]} } map { [ split / / ] } <FILE1
+>;
[download]

I would, however, recommend you use lexical filehandles. See open for examples.

Here's my test (in the spoiler):

Hi

#!/usr/bin/env perl -l

use strict;
use warnings;
use Data::Dumper;

open(TABLE,"<","./table.txt") or die $!;

my %Tables=();

my $eachline;
while( $eachline=<TABLE>)
{
  next if $eachline=~/^$/;
  chomp($eachline);
  my ($value,$key)= split (/\s+/,$eachline);
  $Tables{$key} = $value;
}
print Dumper \%Tables;


open(VALUES,"<","./values.txt") or die $!;

my $eachValue;
while($eachValue=<VALUES>)
{
        chomp($eachValue);

        if (exists $Tables{$eachValue}) {

                print $eachValue Matches in table.txt $Tables{$eachVal
+ue}.qq(\n);
        }
        else {
                print "$eachValue not matched in table.txt file\n";
        }
}
[download]

Update:Including input files.

xanmn_chr09_0114-xanmn_chr09_0114 3346
xanmn_chr09_0129-xanmn_chr09_0129 3358
xanmn_chr09_0116-xanmn_chr09_0116 3348
xanmn_chr09_0127-xanmn_chr09_0127 3354
[download]

3346
1933
1371
1448
2762
1395
[download]

Better to first try coding it with the hints given all by yourself!

If you're wise you code for yourself, but if you're clever you don't stand in the way of people that are willing to do the coding for you (only joking of course).

use Inline::Files;

$h{$a[1]} = $a[0] while @a = split /\s|$/, <TABLE>;
exists $h{$_} and print "$h{$_}\n" while chomp($_ = <VALUES>);



__TABLE__
xanmn_chr09_0114-xanmn_chr09_0114 3346
xanmn_chr09_0129-xanmn_chr09_0129 3358
xanmn_chr09_0116-xanmn_chr09_0116 3348
xanmn_chr09_0127-xanmn_chr09_0127 3354

__VALUES__
3346
1933
1371
1448 
2762
1395
[download]