I havn't looked at glutMainloop, but most eventloop systems have a method to force an iteration thru the loop. In Tk, it's DoOneEvent(ALL_EVENTS); and in Gtk2 it is Gtk2->main_iteration while Gtk2->events_pending;

So here is an example of running a Tk eventloop and a Gtk2 eventloop simultaneously.

There is a discussion of doing this for glutMainloop at hacking Glut. AnyEvent seems to have AnyEvent->loop; to force one iteration. So possibly you could setup a glut timer to run AnyEvent->loop; every 10 milliseconds, or whatever rate you need.

#!/usr/bin/perl -w
use strict;
use Gtk2;
use Tk;

#setup Tk loop
my $mw = MainWindow->new(-title=>'Tk Window');
my $count_tk = 0;
my $labtk = $mw->Label(-textvariable =>\$count_tk)->pack; 

#setup Gtk2 loop
Gtk2->init;
my $count_gtk = 0;
my $window = Gtk2::Window->new('toplevel');
$window->set_title('Gtk2 Window');
my $glabel = Gtk2::Label->new("This is a  Gtk2 Label $count_gtk");
$window->add($glabel);
$window->show_all;

# make Tk loop the master, but you could make Gtk2 master if desired
# the lower the repeat rate, i.e. 1 ms, 
# will give more cpu time to the gtk2 loop
# this is sometimes called manually pumping the event loop
my $tktimer = $mw->repeat(10, sub{      
   $count_gtk++;
   $glabel->set_text("This is a  Gtk2 Label $count_gtk");
   Gtk2->main_iteration while Gtk2->events_pending;
   
   $count_tk++;
  });


$mw->Button(-text=>' Tk control Quit  ',
       -command => sub{exit}
        )->pack();

MainLoop;

########################################
[download]

From a quick googling, it seems that at least some GLUT implementations, freeglut and openglut implement glutMainLoopEvent(), which is supposed to be called periodically from your other mainloop.

A second alternative would be to detach OpenGL processing from the rest of your program by using a separate thread to handle OpenGL. But then you need to make sure that all OpenGL-related resources get allocated from that thread. At least, I remember some stories of debugging two threads going tag-team on OpenGL handles in the early days of consumer OpenGL.

Thank you, Corion!

I've found that the main trick is to call glutPostRedisplay too, e.g. instead of glutMainLoop

my $refresh_world = sub {
    glutMainLoopEvent;
    glutPostRedisplay;
};
my $t; $t = AE::timer 0, 0.01, sub {
    $refresh_world->();
};
$refresh_world->();
AE::cv->recv;
[download]