use strict;
use warnings;
use Data::Dumper;
use List::Util qw(min max sum);

my %hash;
my @files = ('file1.txt','file2.txt');
for my $file (@files) {
    open(my $fh,"<",$file) or die "$file: $!";
    while (my $line = <$fh>) {
        chomp $line;
        next unless $line;
        my @items = split(/\s+/,$line);
        my $key = shift @items;
        my $total = shift @items;
        $hash{$key}{'sum'} += $total;
        push(@{ $hash{$key}{'points'} }, @items );
    }
    close($fh);
}
for my $key (keys %hash) {
    my $points = $hash{$key}{'points'};
    $hash{$key}{'min'} = min(@$points);
    $hash{$key}{'max'} = max(@$points);
    $hash{$key}{'avg'} = $hash{$key}{'sum'} / @$points;
    # to print the points
    print join(' ',@$points) . "\n";
}
print Dumper(\%hash);
[download]

'8' => {
       'sum' => '29.489759'
       'min' => '2.940214',
       'max' => '3.083707',
       'avg' => '2.9489759',
       'points' => [
                     '3.011583',
                     '2.943297',
                     '2.940214',
                     '2.955738',
                     '2.968009',
                     '3.083707',
                     '2.958022',
                     '2.957737',
                     '2.982671',
                     '2.990788'
                   ],
     },
[download]

#!perl
use strict;
my %data=();

my @data1 = (
'8 14.701072 3.011583 2.943297 2.940214 2.955738 2.968009',
'16 30.561410 6.249463 6.118992 6.124449 6.112282 6.133605',
'32 60.983738 12.254996 12.263543 12.277047 12.291713 12.196748',
'64 116.472912 24.024475 23.347609 23.463421 23.294582 23.336542');

my @data2 = (
'8 14.788687 3.083707 2.958022 2.957737 2.982671 2.990788',
'16 30.368369 6.384345 6.079698 6.073674 6.108037 6.134851',
'32 60.373260 12.492582 12.137764 12.164201 12.074652 12.107912',
'64 117.676048 24.010324 23.535210 23.562157 23.596123 23.675554');

for (@data1,@data2){
  my ($sz,$sum,@f) = split /\s+/;
  push @{$data{$sz}},$_ for @f;
}

for my $sz (sort {$a <=> $b} keys %data){
  print join ' ',@{$data{$sz}},"\n";
}
[download]

Taking poj's nice code to use filehandle:

use strict;
use warnings;
use autodie;

my %data=();
my $file_one = 'test.txt';
my $file_two = 'test2.txt';

open ( my $fh1, '<', $file_one);
open ( my $fh2, '<', $file_two);

my @data1 = <$fh1>;
my @data2 = <$fh2>;

for (@data1,@data2){
  my ($sz,$sum,@f) = split /\s+/;
  push @{$data{$sz}},$_ for @f;
}

for my $sz (sort {$a <=> $b} keys %data){
  print join ' ',@{$data{$sz}},"\n";
}
[download]

UPDATE: if the data files actually contain new lines, chomp($_) in the first for loop

Hi PerlSufi, your code is very fine for the example, but it does not scale up very well for more than two files (and the OP mentioned that there are multiple data files).

I would probably avoid storing each file into individual arrays, and try to process each file sequentially, and change the code to something like this (incomplete and obviously untested):

use strict;
use warnings;

my %data=();
for my $file (qw /file_1.txt file_2.txt, file_3.txt ... file_n.txt/) {
     open my $FH, "<", $file or die "could not open $file $!";
     while (<$FH>) {
          chomp;
          my ($sz,$sum,@f) = split /\s+/;
          push @{$data{$sz}},$_ for @f;
     }
     close $FH;
}
# ...
[download]

Or possibly, if the files are passed as arguments to the script:

use strict;
use warnings;

my %data=();
for my $file (@ARGV) {
     open my $FH, "<", $file or die "could not open $file $!";
     while (<$FH>) {
          # ...
     }
     # ...
}
# ...
[download]

or even (still assuming the files are passed as arguments):

use strict;
use warnings;
use autodie;

my %data=();
while (<>) {
     chomp;
     # ...
}
#...
[download]

This latest solution might be used even if the argument passed to the script is not a list of files, but, say, the directory where they are stored:

use strict;
use warnings;
use autodie;

my $stat_dir = shift;
my %data = ();
 
{
     local @ARGV = glob ("$stat_dir/*.*");
     while (<>) {
          chomp;
          # ...
     }
     # ...
}
[download]

Admittedly, the latest solutions look less robust and one might want to avoid them for production code. But are they really less robust? Hmm, if glob returns a list of files, then you basically know the files are there, the only thing that is lacking might be checking read privileges, no big deal.

#!/usr/bin/perl -w

use strict;
use warnings;
use v5.10;

my $completeDataPtRef;

for my $slot (1 .. 2) {
      my $TestFileName = "Slot". $slot ."Simplex.cfg.data";
      open my $dataFile, '<', "$TestFileName" or die ("Unable to open 
+file $TestFileName: $!\n");
      my $dataSetCnt = 0;
      while (my $dataLine = <$dataFile>)
      {
         $dataLine =~ /^#/ and next;
         my @dataPts = split(/\s+/, $dataLine);
         my $dataSetSize = shift(@dataPts);
         my $totalThroughput = shift(@dataPts);         
         
         push @{$completeDataPtRef->[$dataSetCnt]}, @dataPts;
         ++$dataSetCnt;
     }
     close $dataFile;
}

for my $linevalues (@{$completeDataPtRef})
{
     print "@{$linevalues}\n";
}
[download]