f_ext was added in DBI-1.608 and DBD::CSV-0.25, so that should work. f_encoding however was added in DBI-1.611, so that will not.

You did not mention the version of SQL::Statement, which is the SQL parser for DBD::CSV and essential for almost any statements more complicated than select foo from bar;. You use LIKE.

If you want to use literal key names, you can almost never rely on its casing the way you do. You should tell DBI explicitly to return your key names in upper case or lower case when using fetchrow_hashref. Better yet, do not rely on this at all

The case insensitiveness for table names should work as of DBD::CSV-0.25, so you should be safe there too.

Use a CSV module to output your data!

use warnings;
use strict;
use DBI;
use Text::CSV_XS;

# Create connection string to database point.csv 
my $dbh = DBI->connect ("dbi:CSV:", undef, undef, {
    # CSV specific attributes
    f_ext              => ".csv/r",
    f_encoding         => "utf-8",
    # DBI attributes
    RaiseError         => 1,
    PrintError         => 1,
    ChopBlanks         => 1,
    ShowErrorStatement => 1,
    FetchHashKeyName   => "NAME_uc", # You want uc (I prefer lc)
    });

my $sth = $dbh->prepare ("select * from point where ID_DEVTYP like 'IN
+TELI%' AND ID_POINT like 'AUTO%'");
$sth->execute;
my @columns = @{$sth->{NAME_uc}};

# Create AFS CSV with Columns
my $csv = Text::CSV_XS->new ({ binary => 1, eol => "\r\n" });
open my $fh, ">", "AFS.csv" or die "AFS.csv: $!";
$csv->print ($fh, \@columns);

# Cycle through SQL results on ROW basis and print to AFS CSV file
while (my $row = $sth->fetchrow_hashref) {
    $csv->print ($fh, [ @{$row}{@columns} ]);
    }
# Close file    
close $fh;
[download]

With Text::CSV_XS-1.07 you can even simplify that to:

use Text::CSV_XS qw( csv );
:
:
my $sth = $dbh->prepare ("select * from point where ID_DEVTYP like 'IN
+TELI%' AND ID_POINT like 'AUTO%'");
$sth->execute;

csv (out => "AFS.csv", in => sub { $sth->fetchrow_hashref });
[download]

#!perl
use warnings;
use strict;
use DBI;

my @col = qw(RECORD      SUBSCRIPT ID_SUBSTN CO_SUBSTN 
             AREA_SUBSTN ID_DEVTYP ID_DEVICE NAME_DEVICE 
             AREA_DEVICE ID_MEAS   ID_POINT  SITE_POINT AREA_POINT);
my $cols = join ",",@col;

# Create connection string to database point.csv 
my $dbh = DBI->connect ("dbi:CSV:", undef, undef, {
      f_ext      => ".csv/r",
      f_encoding => "utf-8",
      });

my $sth = $dbh->prepare ("SELECT $cols FROM point 
                          WHERE ID_DEVTYP LIKE 'INTELI%' 
                            AND ID_POINT  LIKE 'AUTO%'");
$sth->execute;

# Create AFS CSV with Columns
open DAT_OUTPUT,'>','AFS.csv' or die "Could not open AFS.csv : $!";
print DAT_OUTPUT $cols."\n";

# Cycle through SQL results on ROW basis and print to AFS CSV file
while (my @row = $sth->fetchrow_array) {
  print DAT_OUTPUT (join ",",@row)."\n";   
}
# Close file    
close DAT_OUTPUT;
[download]

Thank you for your response. Here is a Challenge Your code works in v5.10.1 Binary build 1007 291969 but not Binary build 1006 291086 My former code worked in Build 1006 but not 1007. point.csv does exist.. in the same directory Here is my error message.. still peculiar to a file open issue. The File.pm is ~2009 on the 1007 build and ~2008 on the 1006 build.

C:\....>afs_filter.pl

Execution ERROR:  Cannot open point: No such file or directory at C:/P
+erl64/lib/DBD/File.pm line 579.
.

DBD::CSV::st fetchrow_array failed: Attempt to fetch row without a pre
+ceeding execute() call or from a non-SELECT statement [for Statement 
+"SELECT RECORD,SUBSCRIPT,ID_SUBSTN,CO_SUBSTN,AREA_SUBSTN,ID_D
EVTYP,ID_DEVICE,NAME_DEVICE,AREA_DEVICE,ID_MEAS,ID_POINT,SITE_POINT,AR
+EA_POINT FROM point WHERE ID_DEVTYP LIKE 'INTELI%' AND ID_POINT  LIKE
+ 'AUTO%'"] at C:\....afs_filter.pl line 53.
[download]

Any ideas? Thanks

It is extremely rare that the "binary build" matters ; Its the module versions that matter; upgrade; see what you use with Devel::VersionDump