Something like:

 print pos while /substr/g ¹

edit

Though you might need to subtract the length of the match if you need the start position.

Of course TIMTOWTDI. :)

update

¹) corrected for to while

test:

  DB<107> $_='abcd'x4
 => "abcdabcdabcdabcd"

  DB<108> print pos()-2 while m/ab/g 
04812
[download]

Using substring and iterating over the string seems simple enough, and it would work alright.

If you want to use a regex, you should use look ahead assertions if you want to find occurrences that can overlap (and for pos to give you the start of the match). :

perl -E 'for("bababa") { say pos while /(?=baba)/g }'
0
2
[download]

If you don't want to find overlapping occurrences, you can use @- to find the start of the last match.

perl -E 'for("bababa") { say $-[0] while /baba/g }'
0
[download]

($-[0] will work in the former too.)

Hi,

Yes, You need to loop over index() function to find every occurrence of a substring in a string.

Example:

#!/usr/bin/perl
use strict;
use warnings;

my $string = 'every occurrence of a substring in a string';
my $char = 'st';
my $offset = 0;

my $result = index($string, $char, $offset);

while ($result != -1) {

        print "Found $char at $result\n";

        $offset = $result + 1;
        $result = index($string, $char, $offset);

}
[download]

The above code finds the substring 'st' in the string.

Found st at 25

Found st at 37

my @poss;
my $pos = -1;
while (($pos = index($string, $char, $pos + 1)) != -1) {
  push @poss, $pos;
}
[download]

Read perldoc perlvar. pos gives you the last position of the match. Instead:

perl -e '$str = q|aaabbbcccddd|; while($str=~m/(\S)\1\1/g){print @-[0]
+};'

0369
[download]