Ok, i've come across this example of recursion from another user on this forum BrowserUk But i'm having trouble understanding it. Could anyone help?

Re^3: Variable number of foreach loops

The code is below:

#! perl -slw
use strict;

sub nForX(&@) {
    my $code = shift;
    my $n = shift;
    return $code->( @_ ) unless $n;
    for my $i ( @{ shift() } ) {
        &nForX( $code, $n-1, @_, $i );
    }
}

my @a = 1..10;
my @b = 'a'..'z';
my @c = map chr, 33 .. 47;

nForX {
    print join ' ', @_;
} 3, \( @a, @b, @c );
[download]

Anyone? Thanks.

OK, I’ll have a go at explaining how this works. But note first that BrowserUk produced his elegant solution by exploiting some of the less-well-known features of Perl syntax. Let’s get them out of the way first:

Read more... (2 kB)

Now to the recursion. (1) On the first call, $code is initialised to the block { print join ' ', @_; }, and $n is set to 3. As 3 is non-zero, the call to return $code->(@_) is skipped. The for loop which follows is equivalent to this:

for my $i (1, 2, 3, 4, 5, 6, 7, 8, 9, 10)
{
    &nForX($code, 2, \@b, \@c, $i);
}
[download]

The first iteration of this loop calls nForX for the second time, as follows:

&nForX($code, 2, \@b, \@c, 1);
[download]

(2) Within this second call, $code is set as before, and $n is 2. The for loop is now equivalent to this:

for my $i ('a', 'b', 'c', 'd', 'e', 'f', 'g', 'h', 'i', 'j', 'k', 'l',
+ 'm', 'n', 'o', 'p', 'q', 'r', 's', 't', 'u', 'v', 'w', 'x', 'y', 'z'
+)
{
    &nForX($code, 1, \@c, 1, $i);
}
[download]

On its first iteration, it calls nForX for the third time, as follows:

&nForX($code, 1, \@c, 1, 'a');
[download]

(3) Within this third call, $n is 1, and the loop is now this:

for my $i ('!', '"', '#', '$', '%', '&', "'", '(', ')', '*', '+', ',',
+ '-', '.', '/')
{
    &nForX($code, 0, 1, 'a', $i);
}
[download]

On its first iteration, this loop calls nForX for the fourth time, as follows:

&nForX($code, 0, 1, 'a', '!');
[download]

(4) Within this fourth call, $n is now zero, so the sub ends with the statement return $code->(@_);, which is here equivalent to:

return print join ' ', 1, 'a', '!';
[download]

So at this point, the first line of output is printed, and a “true” value is returned to the caller, which was the third call to nForX. That third call throws the return value away, and proceeds to the next iteration of its for loop, which is equivalent to this:

&nForX($code, 0, 1, 'a', '"');
[download]

— and so on and so on, until all the calls to nForX have returned and all the loops are exhausted. (As am I, after all that!)

Hope that helps,

Athanasius <°(((>< contra mundum

Iustus alius egestas vitae, eros Piratica,

Thank you so much for taking the time to explain this code. There was a lot in there that i couldn't get my head around, so your explanation is very much appreciated. I'm actually now using the code so it's good that i now know how it works!!

A final point, i tried to move the subroutine definition below the code calling it (I like to keep all my subs at the bottom), but i get an error:

Can't call method "nForX" without a package or object reference at ./test.pl line 617.

Is there a reason for this? And how do i store the sub somewhere else?

Any tips on where to start with that? I'm googling recursion but it looks massively complicated.