Yes something similar like you wrote!! Do you suggest any better way to do that?

My end goal is to create an HTML page, which will display a Column Chart. Each column is each $customer, who has its value drawn.

In bussiness, we have everyday new customers, and so the myHash will change everyday when I run the Script to get the data (which customers did visit us today). That can be completely direferent than yesterday (the names of $customer).

I am trying to find a good way to filter through myHash each $customer with it's representing value (money).

I noticed I have always written here that there is only one possible value from $customer. THIS IS NOT TRUE! My mistake.

foreach $customer(keys %myHash){
$money_spent_9am = $myHash{$customer}{money9am};
$money_spent_3pm = $myHash{$customer}{money3pm};
}
[download]

Again, correct me if I'm wrong -- what you'd like to do in the end is output a table roughly like the following:

 Customer        | Money spent
-----------------+-------------
 Fred Flintstone | 1000
 Barney Rubble   | 2000
 ...             | ...
[download]

I'll assume from this point on that that's the case.

How to best go about this depends on how %myHash is structured, exactly. If it's a hash of hashes, holding (for each customer) a hash with several pieces of information, including the money they spent, proceed as in Re: Keys and Values from Hash to obtain a hash containing only, for each customer, the amount of money they spent. Your original post suggests that this is the case.

If it's already a hash of that form, you're done. Your reply at Re^2: Keys and Values from Hash suggests that this is the case instead.

Either way, once you've got the resulting hash, simply iterate over it and output HTML in some way to create your page:

foreach my $customer (keys %money_spent) {
    my $money_sent_by_this_customer = $money_spent{$customer};
    
    # do something with $customer and $money_spent_by_this_customer

}
[download]

That said, you may not even need to do any of this; you could equally well just do this, obviating the need for an intermediate hash entirely:

foreach my $customer (keys %myHash) {
    my $money_sent_by_this_customer = $myHash{$customer}->{"money"};
    
    # do something with $customer and $money_spent_by_this_customer

}
[download]

I hope this helps.

BTW, I'm getting the feeling that you're not so familiar/at ease with the concept of hashes as such yet. Be sure to read up on them -- see Associative array, Programming Perl p. 76-77 (page numbers for 3rd edition), perldata, perlfaq4: Data: Hashes (Associative Arrays), Not Exactly a Hash Tutorial, Perl Hash Howto, etc.

EDIT: re: your added important info, if you've only got two data points for each customer, money spent at 9am and money spent at 3pm, I'd recommend simply using two separate hashes, each constructed as above. That, or (again) don't use intermediate hashes at all, and just do this:

foreach my $customer (keys %myHash) {
    my $money_sent_by_this_customer_at_9am = $myHash{$customer}->{"mon
+ey9am"};
    my $money_sent_by_this_customer_at_3pm = $myHash{$customer}->{"mon
+ey3pm"};
    
    # do something with $customer, $money_spent_by_this_customer_at_9a
+m and $money_spent_by_this_customer_at_3pm

}
[download]

My end goal is to create an HTML page, which will display a Column Chart

In that case, here's a long pass up the field for you ..

#!perl;
use strict;
use GD;
use GD::Graph::bars;

# test data
my %spend = ();
for ('A'..'Z'){
  $spend{'Customer_'.$_} = { 
    money9am => int rand(1000), 
    money3pm => int rand(1000) };
}; 

# graph
my $date = scalar localtime;
my $graph = GD::Graph::bars->new(800,400);
$graph->set( 
  y_label     => 'Spend',
  title       => 'Customer spend for '.$date,
  bar_spacing => 5,
  cycle_clrs  => 1,
  x_labels_vertical => 1,
) or die $graph->error;
$graph->set_x_axis_font(gdMediumBoldFont);
$graph->set_y_axis_font(gdMediumBoldFont);
  
# table and graph data
my @x=(); my @y=();
my $table = q!<table cellspacing="0" cellpadding="5" border="1">!;
for my $cust (sort keys %spend){
  my $spend = $spend{$cust}{'money9am'}+$spend{$cust}{'money3pm'};
  push @x,$cust;
  push @y,$spend;
  $table .= qq!<tr><td>$cust</td><td align="right">$spend</td></tr>!;
}
$table .= q!</table>!;

# plot
my $gd = $graph->plot([\@x,\@y]) or die $graph->error;
  
# save chart as gif
(my $filename = $date) =~ s/ /_/g; 
$filename =~ s/://g;
open IMG, '>',$filename.'.gif' or die $!;
binmode IMG;
print IMG $gd->gif;
  
# create html
open HTM, '>report.htm' or die $!;
print HTM qq(<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN"  "http:
+//www.w3.org/TR/html4/strict.dtd">
<head><title>Spend for $date</title></head>
<body><h3>Spend for $date</h3>
<p><img src="$filename.gif" alt="chart"></p>
$table
</body></html>);
[download]

For more graph options see GDGraph
poj