@statements = sort by_date @statements;

sub by_date {
    my $dateA = $a->{statement_date};
    my $dateB = $b->{statement_date};
    $dateA =~ s!(\d\d)/(\d\d)/(\d\d\d\d)!$3$1$2!;
    $dateB =~ s!(\d\d)/(\d\d)/(\d\d\d\d)!$3$1$2!;
    $dateA cmp $dateB;
}
[download]

You could also use a date parsing module such as Date::Parse and do a Schwartzian Transform:

use Date::Parse;

# ...

my @statements =
    map  { $_->[1]                                  }
    sort { $a->[0] <=> $b->[0]                      }
    map  { [ str2time($_->{'statement_date'}), $_ ] }
    @statements;
[download]

Other date-parsing modules that might be of interest include Date::Manip, HTTP::Date, and Time::ParseDate.

Or, you can use Time::Piece (core since 5.10) and Orcish Maneuver:

my %cache;
@sorted = sort {
    ( $cache{$a} //= 'Time::Piece'->strptime($a->{statement_date}, '%m
+/%d/%Y') )
      <=>
    ( $cache{$b} //= 'Time::Piece'->strptime($b->{statement_date}, '%m
+/%d/%Y') )
} @statements;
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ