in reply to Calculations before using lib;

To call the code during the compilation phase when use is resolved, use the BEGIN block: 
use FindBin qw($Bin);
my $dir;
BEGIN {
    if ($Bin =~ /^(\/.+\/monkeyman\/bin)(\/.+)?/) {
    $dir = "$1/lib";
}
use lib $dir;
use MonkeyMan;

[download]

See perlsub for details.

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

Replies are listed 'Best First'.
Re^2: Calculations before using lib;
by ikegami (Patriarch) on Aug 04, 2014 at 16:10 UTC
    hum... passing undef to lib? Fixed: 
    use FindBin qw($RealBin);

my @extra_libs;
BEGIN {
    if ($RealBin =~ /^(\/.+\/monkeyman\/bin)(\/.+)?/) {
        push @extra_libs, "$1/lib";
    }
}

use lib @extra_libs;
use MonkeyMan;

    [download]
    or 
    use FindBin qw($RealBin);

use lib ();
BEGIN {
    if ($RealBin =~ /^(\/.+\/monkeyman\/bin)(\/.+)?/) {
        import->lib("$1/lib");
    }
}

use MonkeyMan;

    [download]

    Note the switch to $RealBin in order to handle symlinks.

[reply]
[d/l]
[select]
Re^2: Calculations before using lib;
by v_melnik (Scribe) on Aug 04, 2014 at 15:09 UTC

    Wow, thank you so much! I thought I've lost my sense %)

    V.Melnik
[reply]
Re^2: Calculations before using lib;
by afoken (Chancellor) on Aug 05, 2014 at 04:40 UTC

    As perl needs to know the arguments for use lib before calling lib's import method, every expression used there is implicitly in a BEGIN block equivalent. So I often use a construct like this in my code:

    #!/usr/bin/perl
use strict;
use warnings;
use FindBin ();
use lib do { (my $dir=$FindBin::Bin)=~s|/foo/|/bar/|; $dir };

    [download]

    This can also be used with taint mode to untaint the value of $FindBin::Bin:

    #!/usr/bin/perl -T
use strict;
use warnings;
use FindBin ();
use lib do { $FindBin::Bin=~m|^(/.*)| or die "Can't find myself"; "$1/
+../lib" };

    [download]

    Alexander

    --
    Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom