in reply to Reg the split expression

You should be able to get your desired result with Non capturing groupings: 
use strict;
use warnings;

my $result = <<'EOT';
transaction 1234567; promote; 2014/08/01 10:22:37 ; user: john
  # Performing a "promote" on file.
  /./abc/desf/test.pl 138699/1 (138700/1) 

transaction 4578643; promote; 2014/08/01 10:22:37 ; user: sam
  /./abc/desf/test.pl 138699/1 (138700/1) 
EOT

while ($result =~ /transaction (\d+).*user:\s*(\S+)\s*(?:#\s*(.*))?/g)
+ {
            my ($transaction, $user, $comment) = ($1, $2, $3);
            printf "%-12s %-10s %s\n", $1, $2, $3//'';
}

[download]

Note the // (Logical Defined Or) to avoid an undef warning in your print.

#11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

Replies are listed 'Best First'.
Re^2: Reg the split expression
by AnomalousMonk (Archbishop) on Aug 04, 2014 at 21:51 UTC

    The  // defined-or operator was introduced in Perl version 5.10, which also introduced the  (?|pattern) "branch reset" extended pattern (see Extended Patterns in perlre), which can be used to similar effect. 

    use 5.010;  # need (?|pattern) "branch reset" regex construct

use strict;
use warnings;

my $result = <<'EOT';
transaction 1234567; promote; 2014/08/01 10:22:37 ; user: john
  # Performing a "promote" on file.
  /./abc/desf/test.pl 138699/1 (138700/1)

transaction 4578643; promote; 2014/08/01 10:22:37 ; user: sam
  /./abc/desf/test.pl 138699/1 (138700/1)
EOT

print qq{[[$result]] \n\n};

while ($result =~ m{
    transaction \s  (\d+) .*?
    user:       \s* (\S+) \s*
    (?| [#] \s* ([^\n]*) | ())  # comment or empty string to $3
    }xmsg) {
    my ($transaction, $user, $comment) = ($1, $2, $3);
    printf "%-12s %-10s %s\n", $transaction, $user, $comment;
    }

    [download]

    Output: 

    c:\@Work\Perl\monks\sravs448>perl alt_branch_reset_1.pl
[[transaction 1234567; promote; 2014/08/01 10:22:37 ; user: john
  # Performing a "promote" on file.
  /./abc/desf/test.pl 138699/1 (138700/1)

transaction 4578643; promote; 2014/08/01 10:22:37 ; user: sam
  /./abc/desf/test.pl 138699/1 (138700/1)
]]

1234567      john       Performing a "promote" on file.
4578643      sam

    [download]

[reply]
[d/l]
[select]
Re^2: Reg the split expression
by sravs448 (Acolyte) on Aug 04, 2014 at 21:18 UTC
    Thanks ..it worked
[reply]

In Section Seekers of Perl Wisdom