If you add use warnings; to the head of your script, Perl will tell you that the opening of the while loop:

while ($i = 1) {
[download]

contains a logic error: it re-initialises the variable to 1 on each loop iteration. In fact, this loop would benefit from a complete re-write:

use strict;
use warnings;

my $c;

for (my ($valid, $try) = (0, 1); !$valid; ++$try)
{
    print "Enter the range of the array (try $try):\n";

    chomp($c = <STDIN>);

    if ($c =~ /^\d+$/)
    {
        print "You have entered a valid range: $c\n";
        $valid = 1;
    }
    elsif ($try < 3)
    {
        print "The input is invalid, please enter digits only\n";
    }
    else
    {
        print "No valid array range entered, exiting\n";
        exit;
    }
}

print "Continuing...\n";
[download]

This is one of the unusual cases in which a C-style for loop is useful in Perl. Please note:

• I have also added use strict; and declared all variables as lexicals with my. The amount of time this will save you down the track far outweighs the (very small) extra effort required.
• In future, please put <code> ... </code> tags around your code, to make it readable.
• When asking a question (as opposed to commenting on someone else’s answer), it’s usually better to open a new thread.

Hope that helps,