Your code doesn't look too problematic in general. However you are preforming string equality tests like this:

but $message is the last field in the line from the input file and isn't being chomped so your string test will likely fail unless you take into account the EOL character(s). If you can correct that (probably best to use chomp to do so) you may have more success.

An additional potential problem is that the lines have a trailing space that should also probably be removed for the equality test to work.

you might want to try this:

use strict;
use warnings;

my ($tot1, $tot2);
while (<DATA>) {
    chomp;
    s/\s+$//g;
    next unless /TP Service Request$/ or /P5 Move request$/;
    my ($datetime, $ms, $inid, $message) = split /,/, $_;
    my $date = substr $datetime,11;
    my ($hours, $min, $sec) = map { $_ * 1000} split /:/, $date;
    $hours *= 60 * 60;
    $min *= 60;
    my $total_time = $hours + $min + $sec + $ms;
    $tot1 = $total_time if $message eq "TP Service Request";
    $tot2 = $total_time if $message eq "P5 Move request";
    next unless defined $tot2;
    print "Duration is: ", $tot2 - $tot1, " ms.\n";
    last;
}
        

__DATA__
2014-05-29 10:22:21,880,165ab6a8-e736-11e3-8748-8d365226be24,TP Servic
+e Request 
2014-05-29 10:22:21,962,165ab6a8-e736-11e3-8748-8d365226be24,ProcessNa
+me: TC 
... (rest of data omitted from this post for brevity)
[download]

$ perl  log_files.pl
Duration is: 46426 ms.
[download]

the total time is almost figured out ; i cant seem to think of a way to get process time without writing inefficient & repetitive code :(

the total time is almost figured out ; i cant seem to think of a way to get process time without writing inefficient & repetitive code :(

Congratulations, you are about to start programming, start naming subroutines, subroutines that take arguments and return values, and die on critical errors (like can't open file), subroutines with meaningful names that make sense in the context of your application, subroutines whose names are part of your application vocabulary/glossary

perlintro#Writing subroutines and http://learn.perl.org/books/beginning-perl/ Chapter 8: Subroutines

Consider using a database perhaps ?

#!perl
use strict;    
use warnings;
use DBI;

#create db
my $dbfile = 'database.sqlite';
unlink($dbfile);
my $dbh = DBI->connect('dbi:SQLite:dbname='.$dbfile , undef , undef , 
                {RaiseError =>1, AutoCommit =>0}) or die $DBI::errstr;
$dbh->do('CREATE TABLE DATA (F1 datetime,F2 INTEGER,F3,F4)'); 
$dbh->do('CREATE TABLE STARTED (F1 datetime,F2,F3)'); 
$dbh->commit;

# load data
my $sth = $dbh->prepare('INSERT INTO DATA VALUES (?,?,?,?)');
while (<DATA>){
  chomp;
  my @f = split ',';
  if (@f==4){
    $sth->execute(@f);
  } else {
    print "Input Line $. Skipped : $_\n";
  }
}
$dbh->commit; 

# select started records
$dbh->do("INSERT INTO STARTED
          SELECT F1,F2,F3 FROM DATA WHERE F4 LIKE '%started%'");
$dbh->commit; 

# calculate duration from start
my $ar = $dbh->selectall_arrayref("
   SELECT D.F1,D.F2,D.F3,D.F4,
   (1000*strftime('%s',D.F1))+D.F2 - (1000*strftime('%s',S.F1))-S.F2
   FROM DATA AS D
   LEFT JOIN STARTED AS S
            ON D.F3 = S.F3");       
for (@$ar){
  printf "@$_\n";
} 

$dbh->disconnect;

__DATA__
[download]

Read more... (3 kB)
poj

thanks this did help me,and i learned a better approach .this is certainly very "dry" :)

use Modern::Perl qw/2014/;
use DateTime;
use DateTime::Format::Flexible;
use DateTime::Duration;

my %data;

while (<DATA>) {
    chomp;
    my ( $datetime, $msecs, $id, $description ) = split /,/;
    $msecs *=1000000;
    $datetime .= ":$msecs";
    my $dt = DateTime::Format::Flexible->parse_datetime($datetime);
    $data{$id}->{$description} = $dt;
}

for my $id ( keys %data ) {
    print "Results for $id: ";
    if (    exists $data{$id}{'P5 Move request'}
        and exists $data{$id}{'TP Service Request'} )
    {
        my $duration = $data{$id}{'P5 Move request'}
          ->subtract_datetime_absolute( $data{$id}{'TP Service Request
+'} );
        say
"$data{$id}{'P5 Move request'} -> $data{$id}{'TP Service Request'} = "
+,
          $duration->seconds + $duration->nanoseconds/1000000000, ' se
+conds';
    }
    else {
        say 'Missing data';
    }
}

__DATA__
2014-05-29 10:22:21,880,165ab6a8-e736-11e3-8748-8d365226be24,TP Servic
+e Request
2014-05-29 10:22:21,962,165ab6a8-e736-11e3-8748-8d365226be24,ProcessNa
+me: TC
2014-05-29 10:22:21,965,165ab6a8-e736-11e3-8748-8d365226be24,P5 Starte
+d
(...)
2014-05-29 07:14:04,048,1770ebca-e722-11e3-b793-c6903cc19f13,P5 Move r
+equest
[download]

Results for 1770ebca-e722-11e3-b793-c6903cc19f13: Missing data
Results for 165ab6a8-e736-11e3-8748-8d365226be24: 2014-05-29T10:23:08 
+-> 2014-05-29T10:22:21 = 46.426 seconds
[download]

Two more comments:

1. If for the same ID you can have multiple processes with the same name, this data-structure is too simple as a later process will overwrite the data of a previous one.
2. Always use a DateTime (or similar) object to represent a datetime. Time and date calculations are fraught with exceptions and special rules. Not all hours are 60 minutes and not all minutes are 60 seconds. The DateTime module takes care of all of that.

Update: Amended code to take into account the millisecond field in the timelog.

i wrote it all right ,took some time .thanks for your help guys .specially laurent_R ,will post the code shortly