#!/usr/bin/perl

use lib 'lib';
use strict;
use warnings;
use feature 'say';
use Data::Dumper;

package Testzool
{
    use Acme::Pool;

    # normal
    has qw'name is rw default rosemary';

    # readonly with default value
    hasrod 'favfood', 'pizza';

    # readwrite with default value
    hasrwd 'age', 111;

    # readonly
    hasro qw'id default 1234567';
    # readwrite
    hasrw 'cash';

    # make has() from string
    hasstr 'height is rw default 1456';

};

package main;

run();

sub run
{
    my $obj = Testzool->new;
    $obj->cash(86);
    say "obj = ", Dumper($obj);
}
[download]

and the Acme::Pool module:

# POOL -> Perl Object Oriented: Extra Lazy
# should have an umlaut on the second O but it fell off.

package Acme::Pool;

use strict;
use warnings;
use feature 'say';
our $VERSION = '0.02';
use Moose();
use Moose::Exporter;

Moose::Exporter->setup_import_methods
    (also => 'Moose',
     with_meta => [ qw/hasrw hasrwd hasro hasrod hasstr/]
    );

sub hasrw
{
    my ($meta, $name, %options) = @_;
    $meta->add_attribute($name, is => 'rw', %options, );
}

sub hasrwd
{
    my ($meta, $name, $default, %options) = @_;
    $meta->add_attribute($name, is => 'rw', default => $default, %opti
+ons, );
}

sub hasro
{
    my ($meta, $name, %options) = @_;
    $meta->add_attribute($name, is => 'ro', %options, );
}

sub hasrod
{
    my ($meta, $name, $default, %options) = @_;
    $meta->add_attribute($name, is => 'ro',  default => $default, %opt
+ions, );
}

sub hasstr
{
    my ($meta, $spec, %options) = @_;
    my @words = split ' ', $spec;
    my $name = $words[0];
    $meta->add_attribute(@words, %options, );
}


return 1; # file loaded successfully
__END__
[download]