Hello aditya1977,

In the spirit of TMTOWTDI, here’s a concise implementation of LanX’s hash slice solution:

#! perl
use strict;
use warnings;
use Data::Dump;

my %nodemetrics;
my @nodelist   =  qw(server1 server2);
my @attributes =  qw(memory cpu disk network);
my $string     = '1024|2200|30|100';
my @data       =  split /\|/, $string;

@{  $nodemetrics{$_     } }{@attributes} = (0) x @attributes for @node
+list;
dd \%nodemetrics;
@{  $nodemetrics{server1} }{@attributes} = @data;
dd \%nodemetrics;
[download]

Output:

22:03 >perl 1027_SoPW.pl
{
  server1 => { cpu => 0, disk => 0, memory => 0, network => 0 },
  server2 => { cpu => 0, disk => 0, memory => 0, network => 0 },
}
{
  server1 => { cpu => 2200, disk => 30, memory => 1024, network => 100
+ },
  server2 => { cpu => 0, disk => 0, memory => 0, network => 0 },
}

22:03 >
[download]

Hope that helps,

Thanks so much for your help guys. I mostly get this now!

Just one last question. If I wanted to return the attributes of one of the servers as a hash, how do I get to that data?

So in other words, I want to a create a simple hash %server_properties which name value pairs of one of the servers?

This creates a copy (NOT an alias i.e. writing to it won't change the original data)

 %server_properties = %{$nodemetrics{server1}}

Otherwise

$h_server1 = $nodemetrics{server1}

(like already shown) is the same hashref, which can be safely changed

$h_server1->{cpu}=100 or alternatively $$h_server1{cpu}=100

see perlref and perldsc for details!

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

Hi aditya1977

Lets try this one.

use strict;
use warnings;
use Data::Dumper;

my %nodemetrics;

my @nodelist = qw(server1 server2);

my @system_attributes = qw(memory cpu disk network);

# Initialise the hash with zeros

my ($node);
foreach $node (@nodelist) {

        foreach (@system_attributes){
                $nodemetrics{$node}{$_} = 0;
        }
}

print Dumper(\%nodemetrics);

my $string="1024|2200|30|100";
my @data = split(/\|/,$string);

my @keys = keys %{$nodemetrics{'server1'}};

my $hashref = $nodemetrics{'server1'};

@$hashref{@keys}=@data;
$nodemetrics{'server1'}=$hashref;
print Dumper (\%nodemetrics);
[download]

my @keys = keys %{$nodemetrics{'server1'}};
[download]

in a somewhat recent perl this leads to:

$ perl scratch.pl 
[...]
          'server1' => {
                         'memory' => '1024',
                         'network' => '2200',
                         'cpu' => '30',
                         'disk' => '100'
                       },
[...]

$ perl scratch.pl
[...]
          'server1' => {
                         'disk' => '1024',
                         'memory' => '2200',
                         'cpu' => '30',
                         'network' => '100'
                       }
[...]
[download]

OUCH!!

You already have the keys in the correct order available, why not use that?

my @system_attributes = qw(memory cpu disk network);

[...]

my $hashref = $nodemetrics{'server1'};
@$hashref{@system_attributes}=@data;
[download]

Caution order matters!

PS: and plz have a look at the links provided.