Hello ray15, and welcome to the Monastery!

Here’s a solution using Text::CSV_XS:

File “1.csv”

fragment,id,index
accb,10,A
bbc,11,B
ccd,12,C
[download]

File “2.csv”

fragment,id,index
bbc,14,E
ccd,15,D
llk,11,B
kks,12,C
[download]

Script in file “main.pl”

#!perl
use strict;
use warnings;
use List::MoreUtils 'uniq';
use Text::CSV_XS;

my %files = (file1 => '1.csv', file2 => '2.csv');
my %hashes;
my $csv   = Text::CSV_XS->new( { binary => 1 } );

for my $file (keys %files)
{
    open(my $in, '<', $files{$file})
        or die "Cannot open file '$files{$file}' for reading: $!";

    <$in>;      # Discard column headings

    while (my $row = $csv->getline($in))
    {
        my $key = shift @$row;
        $hashes{$file}{$key} = [ @$row ];
    }

    close $in
        or die "Cannot close file '$files{$file}': $!";
}

separator_line();
print join("\t", qw(frag id1 file1 id2 file2)), "\n";
separator_line();

my   @keys;
push @keys, keys %$_ for values %hashes;
     @keys = uniq @keys;

for my $fragment (sort @keys)
{
    my $f1 = exists $hashes{file1}{$fragment} ? 1 : 0;
    my $f2 = exists $hashes{file2}{$fragment} ? 1 : 0;

    printf "%s\t%s\t%s\t%s\t%s\n",
            $fragment,
            $f1 ? $hashes{file1}{$fragment}->[0] : '',
            $f1,
            $f2 ? $hashes{file2}{$fragment}->[0] : '',
            $f2,
}

separator_line();

sub separator_line
{
    print '-' x 37, "\n";
}
[download]

Output:

13:06 >perl main.pl
-------------------------------------
frag    id1     file1   id2     file2
-------------------------------------
accb    10      1               0
bbc     11      1       14      1
ccd     12      1       15      1
kks             0       12      1
llk             0       11      1
-------------------------------------

13:07 >
[download]

Note: I do not try to access $hashes{file1}{$fragment}->[0] until I have confirmed that $hashes{file1}{$fragment} already exists in the hash. This is to avoid autovivification, which is a great Perl feature but is not wanted in this case. (See e.g. Uri Guttman’s tutorial for the gory details.)

Hope that helps,

Your question is barely readable, your code does not compile (you still have file3 all over the code), and you are declaring the use of a Text::CSV module without making use of it anywhere in the code. This has homework written all over it.

Still, for someone with a similar problem, a solution could help. Let's define a problem: we have a few files, organized in columns. The first column is the ID, the second is an item name, the rest are not interesting from our point of view. We are making a few assumptions for the input - the ID's cannot be equal to 0, and there is only one line in a file for a given item name.

The input:

 
### test1.csv ###
1  aaa  ignored_field
3  ccc ignored_field
4  ddd ignored_field

### test2.csv ###
11 aaa ignored_field
22 bbb ignored_field
44 ddd   ignored_field

### test3.csv ###
333 ccc ignored_field
555 eee ignored_field
666  fff   ignored_field
777  ggg   ignored_field
[download]

What we want to accomplish is to produce a report with all items, clearly stating the ID under which an item is stored in a file. If a file does not contain this item, instead of the ID, a 0 will be shown.

#!/usr/bin/perl
use v5.14;

my %data;

sub cnt_fields {
    my @fields = split "\t", $_[0];
    return scalar @fields;
}

sub gather_file {
    state $count = 0;
    return $count unless @_;

    my ($filename, $d) = @_;
    open my $fh, "<", $filename;
    while (<$fh>) {
        chomp;
        my @field = split;
        my $offset = $count - cnt_fields($d->{$field[1]});
        $d->{$field[1]} .= "0\t" x $offset;
        $d->{$field[1]} .= "$field[0]\t";
    }
    close $fh;

    for my $key (keys %$d) {
        if (cnt_fields($d->{$key}) <= $count) {
            $d->{$key} .= "0\t";
        }
    }
    $count++;
}

for (1..3) {
    gather_file("test$_.csv", \%data);
}

my $header = "Key\t";
for (1..gather_file()) {
    $header .= "f$_\t";
}
say $header;

for my $key (sort keys %data) {
    say "$key\t$data{$key}";
}
[download]

The output:

$ ./report.pl 
Key    f1    f2    f3
aaa    1    11    0    
bbb    0    22    0    
ccc    3    0    333    
ddd    4    44    0    
eee    0    0    555    
fff    0    0    666    
ggg    0    0    777
[download]

regards,
Luke Jefferson

You define 5 columns in your output, but your samples have either 3 or 4 columns. The file_3 code is pointless (actually, worse than, because it will cause a compilation error). You need both the fragment and the id from each file, but you store only the first as the hash key.

Perhaps you need to replace the scalar value that indicates which file with a more sophisticated data structure that store all the information you need. Then you can generate your output from the hash values.