Cross-posted at StackOverflow

You wrote:

my $csv = Text::CSV->new({
                sep_char => ",",
                binary => 1,
                auto_diag => 1 });
[download]

but your data has no commas in it. How do you expect that to work?

How do you expect us to help you with your program if you don't show it?

Text::CSV_XS has many highly convenient functions for reading and writing CSV files.

Your script is hard to read indeed. Not just because you got confused on how to do the work, but also because of bad names. First, if your variables are numbered (like @row1, @row2), there's a high chance that it would be a good idea to put them in an array, or change their name. In your case, @previousRow and @currentRow would have been far more explicit. I have no idea what $flag and $flag1 are used for, but I'm sure they could have better names. And BTW, you should avoid $flag++ if the only values $flag can take are 0 or 1. Write $flag = 1; instead.

Now, for your issue, there is an association that is often useful in perl: unique means hash. If you want only one record for each unique amount, amountId and MRP combinaison, put them in a hash as keys, and the rest of the values in the associated value.

# I didn't copy the top of your file, and you should add use Data::Dum
+per; if you want this code to work
my $header = $csv->getline($FH);
my @keys = @$header;
my %result;

while (my $row = $csv->getline($FH))
{
  my %currentRow;
  @currentRow{@keys} = @$row;
  print "Current row: ", Dumper \%currentRow;
  my $uniqueKey = "$currentRow{Amount} & $currentRow{AmountId} & $curr
+entRow{MRP}"; # Bad idea if '&' is allowed in either of those values
  if(!exists $result{$uniqueKey}) # If this combinaison is unknown
  {
    $result{$uniqueKey} = [\%currentRow]; # save the current row to it
  }
  else
  {
    push @{ $result{$uniqueKey} }, \%currentRow; # add the current row
+ to the ones with the same ID
  }
}

print "Result: ", Dumper \%result;
[download]

Edit: or the short version following AnomalousMonk's post:

while (my $row = $csv->getline($FH))
{
  my %currentRow;
  @currentRow{@keys} = @$row;
  print "Current row: ", Dumper \%currentRow;
  my $uniqueKey = "$currentRow{Amount} & $currentRow{AmountId} & $curr
+entRow{MRP}"; # Bad idea if '&' is allowed in either of those values
  push @{ $result{$uniqueKey} }, \%currentRow; # add the current row t
+o the existing ones
}

print "Result: ", Dumper \%result;
[download]

if(!exists $result{$uniqueKey}) # If this combinaison is unknown
   {
     $result{$uniqueKey} = [\%currentRow]; # save the current row to i
+t
   }
   else
   {
     push @{ $result{$uniqueKey} }, \%currentRow; # add the current ro
+w to the existing ones
   }
[download]

The exists test is not needed because autovivification (see perlglossary) will create an empty anonymous array reference to push a new value into in the case of a key that does not already exist:

c:\@Work\Perl\monks>perl -wMstrict -le
"use Data::Dump;
 ;;
 my @ra = qw(foo a  bar w  bar x  foo b  bar y);
 dd \@ra;
 ;;
 my %hash;
 while (@ra >= 2) {
   my $k = shift @ra;
   my $v = shift @ra;
   ;;
   push @{ $hash{$k} }, $v
   }
 dd \%hash;
 ;;
 @ra = qw(foo A  bar W  bar X  foo B  bar Y);
 dd \@ra;
 ;;
 my $hashref;
 while (@ra >= 2) {
   my ($k, $v) = splice @ra, 0, 2;
   push @{ $hashref->{$k} }, $v;
   }
 dd $hashref;
"
["foo", "a", "bar", "w", "bar", "x", "foo", "b", "bar", "y"]

{ bar => ["w", "x", "y"], foo => ["a", "b"] }

["foo", "A", "bar", "W", "bar", "X", "foo", "B", "bar", "Y"]

{ bar => ["W", "X", "Y"], foo => ["A", "B"] }
[download]

Oh, right! I keep forgetting that autovivification isn't just when you do something like $name{KEY}[0][1].

It seems like you're trying to operate on 2-row blocks? Like if the first row meets some match criteria, then meld it into the next row?

...then maybe break up the file into 2-row blocks and use regexes on each one.. Like split it this way:

my @tworows = split /[^\n]+\n[^[n]+\n/, $text;
[download]

then you can just use something like

s/((\w+).+\1.+\1.+)\n(.+)/something/
[download]

then repeat that starting on the first even row (because the regex always checks the FIRST row for matches). Much simpler than storing all those temporary arrays, whiles, ifs, etc.

But here are few recomendations:

1. 
next; 
}

is the same as 

}

2. Don't make a copy of your row array to use it, just dereference it:

my @row1 = @{$row}; # not needed..

Just use $row->[$index] instead of $row1[$index]


3. drop all the extra parens
  join ';', @arr;
  push @arr, 'something';


4. it looks like you're using a numeric == to compare ascii fields lik
+e $row1[0] == $row2[0] when col 0 contains things like 'PF'. Use eq f
+or these compares. You can't use == there.
[download]

Amount,ChoiceId,Allowed PID,AmountId,MultiplyingFactor,PF new,ServiceT
+ax,ExtraTalkTime,MRP,Recharge Type,FRC/SRC
13,na,285,100,1.1236,81.75,0.02,0,92,Freebie(BA)+PID,Normal
59,na,285,101,1.1236,8.31,0.07,0,10,Freebie(BA)+PID,Normal
13,na,289,100,1.1236,81.75,0.05,0,92,Freebie(BA)+PID,Normal
2001,na,285,103,1.103,27.13,2.06,0,52,MA+DataPack+PID,Normal
1572,na,285,104,na,0,na,na,na,"Blank MRP,rest OK",Normal
1574,na,285,105,na,0,na,na,na,"Blank MRP,rest OK",Normal
333300,na,285,106,1,0,0,0,3333,Freebie(BA)+MA+PID ,Normal
93,na,285,107,1.1236,100.53,0.11,0,114,Freebie(BA)+PID+SA,Normal
78,na,285,108,1.1236,8.12,0.1,0,10,Freebie(BA)+PID,Normal
79,na,285,109,1.1236,85.54,0.1,0,97,BA20 only,Normal
13,na,290,100,1.1236,81.75,0.11,0,92,Freebie(BA)+PID,Normal
[download]

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Table;

my $dt = Data::Table::fromCSV("data.csv");

# print "DATA:\n";
# print $dt->csv;

# All of the columns except the ones you want to aggregate 
my $cols = [
    'Amount',
    'AmountId',
    'MRP',
    'ChoiceId',
    'MultiplyingFactor',
    'PF new',
    'ExtraTalkTime',
    'Recharge Type',
    'FRC/SRC'
];


my $mdt = $dt->melt( $cols );

# print "MELT:\n";
# print $mdt->csv;

my $cdt = $mdt->cast(
    $cols,
    'variable',
    Data::Table::STRING,
    'value',
    \&aggregate
);

#print "CAST:\n";
#print $cdt->csv;

exit;

sub aggregate {
    my @values = @_;
    my $av = join(';', @values);
    return($av);
}
[download]

Amount,AmountId,MRP,ChoiceId,MultiplyingFactor,PF new,ExtraTalkTime,Re
+charge Type,FRC/SRC,Allowed PID,ServiceTax
13,100,92,na,1.1236,81.75,0,Freebie(BA)+PID,Normal,285;289;290,0.02;0.
+05;0.11
59,101,10,na,1.1236,8.31,0,Freebie(BA)+PID,Normal,285,0.07
2001,103,52,na,1.103,27.13,0,MA+DataPack+PID,Normal,285,2.06
1572,104,na,na,na,0,na,"Blank MRP,rest OK",Normal,285,na
1574,105,na,na,na,0,na,"Blank MRP,rest OK",Normal,285,na
333300,106,3333,na,1,0,0,Freebie(BA)+MA+PID ,Normal,285,0
93,107,114,na,1.1236,100.53,0,Freebie(BA)+PID+SA,Normal,285,0.11
78,108,10,na,1.1236,8.12,0,Freebie(BA)+PID,Normal,285,0.1
79,109,97,na,1.1236,85.54,0,BA20 only,Normal,285,0.1
[download]