Re^2: Perl appending \ or / based on windows or linux

(Note: This is a reply equally to kennethk, jonadab, and anon)

sravs448 wants to append a trailing slash (whether or not that's an XY Problem is another topic). Unfortunately, File::Spec, despite being the core module to handle file/pathnames properly and portably, does not provide a method to do this. Most likely that's because "append a trailing slash" is not really a portable concept across all these supported OSes.

As long as the script is limited to a known set of OSes, McA's suggestion above is probably better in this case.

If there was a solution with a core module (perhaps I've missed something*), that'd make me happy, since I've faced this problem myself before. (Back when I had this problem I didn't find a decent CPAN module either.)

* I tested several variants of catdir / catfile / catpath on the various File::Spec::* implementations (except VMS):

use warnings;
use strict;
use feature 'say';
for my $m (map {"File::Spec::$_"} qw/Unix Win32 Mac OS2
        VMS Cygwin Epoc/) {
    say "##### $m #####";
    eval qq{ use $m; 1 } or warn "Skipping $m because: $@" and next;
    say "        catdir: ", $m->catdir("foo","bar");
    #say "  catdir undef: ", $m->catdir("foo","bar",undef); # warns
    say "  catdir blank: ", $m->catdir("foo","bar","");
    say " catdir curdir: ", $m->catdir("foo","bar",$m->curdir);
    #say " catfile undef: ", $m->catfile("foo","bar",undef); # warns
    say " catfile blank: ", $m->catfile("foo","bar","");
    say "catfile curdir: ", $m->catfile("foo","bar",$m->curdir);
    say " catpath undef: ", $m->catpath(undef,"foo",undef);
    say " catpath blank: ", $m->catpath(undef,"foo","");
    say "catpath curdir: ", $m->catpath(undef,"foo",$m->curdir);
}
__END__
##### File::Spec::Unix #####
        catdir: foo/bar
  catdir blank: foo/bar
 catdir curdir: foo/bar
 catfile blank: foo/bar/
catfile curdir: foo/bar/.
 catpath undef: foo
 catpath blank: foo
catpath curdir: foo/.
##### File::Spec::Win32 #####
        catdir: foo\bar
  catdir blank: foo\bar
 catdir curdir: foo\bar
 catfile blank: foo\bar
catfile curdir: foo\bar
 catpath undef: foo
 catpath blank: foo
catpath curdir: foo\.
##### File::Spec::Mac #####
        catdir: :foo:bar:
  catdir blank: :foo:bar:
 catdir curdir: :foo:bar:
 catfile blank: :foo:bar:
catfile curdir: :foo:bar:
 catpath undef: :foo:
 catpath blank: :foo:
catpath curdir: :foo:
##### File::Spec::OS2 #####
        catdir: foo/bar
  catdir blank: foo/bar
 catdir curdir: foo/bar
 catfile blank: foo/bar/
catfile curdir: foo/bar/.
 catpath undef: foo
 catpath blank: foo
catpath curdir: foo/.
##### File::Spec::VMS #####
Skipping File::Spec::VMS because: Can't locate VMS/Filespec.pm in @INC
##### File::Spec::Cygwin #####
        catdir: foo/bar
  catdir blank: foo/bar
 catdir curdir: foo/bar
 catfile blank: foo/bar/
catfile curdir: foo/bar/.
 catpath undef: foo
 catpath blank: foo
catpath curdir: foo/.
##### File::Spec::Epoc #####
        catdir: foo/bar
  catdir blank: foo/bar
 catdir curdir: foo/bar
 catfile blank: foo/bar/
catfile curdir: foo/bar/.
 catpath undef: foo
 catpath blank: foo
catpath curdir: foo/.
[download]

As you can see Win32 and Mac are the most stubborn.

Comment on Re^2: Perl appending \ or / based on windows or linux Select or Download Code

Replies are listed 'Best First'.
Re^3: Perl appending \ or / based on windows or linux by kennethk (Abbot) on Oct 07, 2014 at 20:51 UTC
dasgar's point about regexing File::Spec aside, it seems like any application that requires a trailing directory separator is really just not using File::Spec enough. Maybe it's my lack of imagination, but short of this literal spec (as you say, XY Problem) I cannot come up with an appropriate use case. #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.	[reply]
Re^4: Perl appending \ or / based on windows or linux by Anonymous Monk on Oct 07, 2014 at 21:39 UTC
A couple of examples from a previous thread: The behavior of rsync sometimes depends on whether a pathname has a trailing slash or not. Often file patterns, such as in gitignore, will match only directories if there is a trailing slash on the name. However, as was argued in that thread, the forward slash is probably fine in all these applications, and so one solution when dealing with them might be `File::Spec::Unix->catdir('foo','bar').'/'` The only other actual use case I could come up with since then is displaying things to a user: a trailing directory separator makes it obvious that something is a path at first glance. So yeah, "I need a trailing slash" is more likely to be an XY Problem than a practical one...	[reply] [d/l]
Re^3: Perl appending \ or / based on windows or linux by dasgar (Priest) on Oct 07, 2014 at 20:34 UTC
You should be able to use a combination of File::Spec and a regex to dynamically determine what the seperation character is - provided that the regex contains all possible seperation characters. `use strict; use warnings; use File::Spec::Functions qw(:ALL); use feature 'say'; my $testpath = catdir('foo','bar'); #say $testpath; my $sepchar; ($sepchar) = ($testpath =~ m/(\\\|\/)/); say $sepchar;` [download] Not sure that this is any better than using $^O to determine the seperation character, but it one possible method using a core module. In either case, you still need to know the valid seperation characters for OSes that you intend to support. I guess the only advantage of the code above over using $^O is that you don't need to know the values of $^O for each OS.	[reply] [d/l]
Re^4: Perl appending \ or / based on windows or linux by kennethk (Abbot) on Oct 07, 2014 at 20:39 UTC
Rather than matching the separation character, match the directory names: `use strict; use warnings; use File::Spec::Functions qw(:ALL); use feature 'say'; my $testpath = catdir('foo','bar'); #say $testpath; my ($sepchar) = $testpath =~ m/^foo(.+)bar$/ or die 'Separation character identification failed'; say $sepchar;` [download] #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.	[reply] [d/l]
Re^5: Perl appending \ or / based on windows or linux by Anonymous Monk on Oct 07, 2014 at 21:39 UTC
Yes, you and dasgar are probably right, if one needs to get the directory separator out of File::Spec. The only caveat I have heard of is that on some OSes, paths aren't that easy... here's a sample VMS filename I found: `DKA0:[MYDIR.SUBDIR1.SUBDIR2]MYFILE.TXT;1` - interesting!	[reply] [d/l]